//  B-Plus interface script for STalker
//
//  Copyright (c) 1992, Eric Rosenquist, Strata Software
//  All rights reserved.
//
//  Exclusive worldwide marketing and distributing by Gribnif Software.
//
//  This file is for the exclusive use of registered STalker¿ owners
//  and may not be distributed, in whole or in part, without the express
//  written permission of Strata Software.


include "stalker.bth"

string  bplus_program[128];
string  dir[128];
string  params[128];

function main() returns int
    int     error;
    string  s;

    // Get the script directory
    get_string_param(PATH_PARAM, PATH_SCRIPT, bplus_program, sizeof(bplus_program));
    // Now strip off the trailing \*.* and change it to \BPLUS.TTP
    if (s = strrchr(bplus_program, '\\')) != NULL then
        strcpy(s, "\\BPLUS.TTP");
    endif

    get_string_param(PATH_PARAM, PATH_DOWNLOAD, dir, sizeof(dir));
    // Strip off the trailing \*.*
    if (s = strrchr(dir, '\\')) != NULL then
        s[0] = 0;
    endif

    sprintf(params, "%s %d %d %d %d %d %d 0", dir,
            get_port(), get_baud(), get_flow_control(), get_word_length(),
            get_stop_bits(), get_parity());

    if not file_exists(bplus_program) then
        printf("The file '%s' was not found.\r\nPlease install the BPLUS.TTP program in your script directory.\r\n",
               bplus_program);
        exit -33;
    endif

    if (error = run_program(bplus_program, params, FALSE)) then
        if error == 1 then
            ;   // Do nothing - just typing UNDO causes error 1
        elseif error == -39 then
            printf("There is not enough memory to execute the BPLUS.TTP utility.\r\n");
        elseif error == -31006 then
            printf("For STalker to execute an external program in accessory mode,\r\nyou must be running either MiNT or NeoDesk.\r\n");
        else
            printf("Error %d running '%s'\r\nPlease consult Appendix G of the STalker manual for an explanation\r\nof the error codes.\r\n",
                   error, bplus_program);
        endif
    endif

    return error;
endfunction