@REM SETUP.BAT; Letterhead Kit/Windows 2.1
@REM Copyright 1992 Jerry Stern--All Rights Reserved, 12/92
@echo off
cls
if not exist ltrwin21.doc goto baddir
if not exist letter-w.frm goto baddir
if not exist letter.wcm goto baddir
if "%1"=="" goto info
if "%2"=="" goto info
if not exist %2\*.* goto nomac
if not exist %1\*.* goto new
ECHO Upgrade Installation to version 2.1
ECHO Your old letterheads will not be replaced.
goto more
:new
ECHO New Installation of version 2.1
:more
ECHO ...
ECHO Files for THE LETTERHEAD KIT 2.1 for WP/Windows will now be copied:
ECHO Macros and the button bar will be copied to %2
ECHO A complete set of all the forms, macros, samples, instructions,
ECHO and graphics will be copied to the directory %1
ECHO You will need about 360K of free space for now, and the manual
ECHO will tell you which files are absolutely needed (about 110K).
ECHO ...
ECHO Press any key to proceed with installation, or Control-C to stop now.
pause > nul
echo %1 >%2\ltrhead.cfg
copy *.wcm %2
copy *.wwb %2
if not exist %1\*.* goto newset
ren %1\*.frm *.old
copy *.* %1\*.*
if exist %1\bill.old del %1\bill.frm
if exist %1\fax.old del %1\fax.frm
if exist %1\letter-w.old del %1\letter-w.frm
ren %1\*.old *.frm
goto done
:newset
md %1
copy *.* %1\*.*
:done
ECHO Done...
ECHO If you haven't already,
ECHO run PRINTMAN.BAT for instructions on printing the manual.
goto end
:nomac
ECHO Letterhead Kit/Windows 2.1 Installation
ECHO The directory that you have chosen to copy the macros and button 
ECHO bar to is empty or doesn't exist. Please check the name,
ECHO and try again.
goto end
:baddir
ECHO Letterhead Kit/Windows 2.1 Installation
ECHO You must start this installation by logging to the drive and directory
ECHO where the files are currently located. When you run SETUP from that
ECHO directory, it will help you find the correct startup command to
ECHO install your software.
goto end
:info
ECHO Letterhead Kit/Windows 2.1 Installation
ECHO Start SETUP.BAT with the new directory name to make for
ECHO storing The Letterhead Kit forms and graphics, and the name
ECHO of the macro directory used by WordPerfect, usually
ECHO c:\wpwin\macros or c:\wpwin.
ECHO ...
ECHO If you don't know where WP/WIN keeps your macros,
ECHO choose File, Preferences, Location of Files, and write
ECHO down the entry under "Macros/Keyboards/Button Bars" and
ECHO enter it from the DOS prompt. (Press Escape to return to
ECHO the document screen.)
ECHO ...
ECHO For example: 
ECHO SETUP c:\ltrhead c:\wpwin\macros
ECHO (Copies package to c:\ltrhead, using c:\wpwin\macros for macros.)
ECHO SETUP d:\ltrhead d:\wpwin
ECHO (Copies package to d:\ltrhead, using d:\wpwin for macros.)
:end
PAUSE