ECHO OFF
CLS
GOTO Top

NAME:    INSTALL.BAT  Shareware Version
PURPOSE: Installation program for "You're Hired!"
VERSION: 14
DATE:    2-20-94

:Top
IF (%1)==(/?) GOTO Help
IF (%1)==(?) GOTO Help
SET Drv=
ECHO    YOU'RE HIRED!                                               INSTALLATION
ECHO    ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
GETYN                Does your computer have a hard drive?
IF ERRORLEVEL 1 GOTO GetDrive
CLS
ECHO                            * INSTALLATION ABORTED *
ECHO    ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
ECHO    If you do NOT have a hard drive, then you do NOT need to "Install" this
ECHO    program. "You're Hired!" will run directly from the disk in your floppy
ECHO    drive. As with any software, it will operate much slower from the floppy
ECHO    drive than from a hard drive.
ECHO.
PAUSE
GOTO README

:GetDrive
CLS
TYPE GETDRIVE.INF
INKEY q99,Q98,g97,G96,f95,F94,e93,E92,d91,D90,c89,C88
CLS
ECHO                              * ONE MOMENT PLEASE *
ECHO    ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
IF ERRORLEVEL 99 GOTO Abort
IF ERRORLEVEL 98 GOTO Abort
IF ERRORLEVEL 97 SET Drv=G
IF ERRORLEVEL 96 SET Drv=G
IF ERRORLEVEL 96 GOTO Drive
IF ERRORLEVEL 95 SET Drv=F
IF ERRORLEVEL 94 SET Drv=F
IF ERRORLEVEL 94 GOTO Drive
IF ERRORLEVEL 93 SET Drv=E
IF ERRORLEVEL 92 SET Drv=E
IF ERRORLEVEL 92 GOTO Drive
IF ERRORLEVEL 91 SET Drv=D
IF ERRORLEVEL 90 SET Drv=D
IF ERRORLEVEL 90 GOTO Drive
IF ERRORLEVEL 89 SET Drv=C
IF ERRORLEVEL 88 SET Drv=C
IF ERRORLEVEL 88 GOTO Drive

:Drive
CLS
CTTY NUL
TYPE zxzxzxzx.$$$ > %Drv%:\datawell.$$$
CTTY CON
IF NOT EXIST %Drv%:\datawell.$$$ GOTO NoDrive
DEL %Drv%:\datawell.$$$
CLS
ECHO    YOU'RE HIRED!                                             INSTALLATION
ECHO    ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
GETYN                  Install "You're Hired!" to drive %Drv%?
IF NOT ERRORLEVEL 1 goto GetDrive
CLS
ECHO                     * INSTALLING TO %Drv%:\YH - PLEASE WAIT *
ECHO    ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
MD %Drv%:\YH
COPY *.* %Drv%:\YH
%Drv%:
IF EXIST \yh.bat del \yh.bat
ECHO ECHO OFF >> \yh.bat
ECHO %Drv%: >> \yh.bat
ECHO cd\yh >> \yh.bat
ECHO yh >> \yh.bat
ECHO cls >> \yh.bat
CD\YH
CLS
ECHO                           * INSTALLATION COMPLETED *
ECHO    ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
ECHO.
PAUSE
GOTO Readme

:Abort
CLS
ECHO                    * INSTALLATION ABORTED AT USER REQUEST *
ECHO    ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
ECHO.
PAUSE
GOTO Readme

:NoDrive
CLS
ECHO                             * INSTALLATION ERROR *
ECHO    ßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßßß
ECHO    Unable to locate drive %Drv%:                Please select another drive
ECHO.
PAUSE
GOTO GetDrive

:Readme
CLS
TYPE Install.end
ECHO.
GOTO End

:Help
ECHO This program will install (copy) "You're Hired" to your hard drive. To use it:
ECHO.
ECHO              1) Place the program disk in drive A or drive B
ECHO              2) Type "A:" or "B:" then press the ENTER key
ECHO                     (Do not type the quotation marks)
ECHO              3) Type "INSTALL" then press the ENTER key
ECHO.
GOTO End
:End