ECHO OFF
CLS
REM -- Test for access to all required files
IF NOT EXIST MANUAL.TXT GOTO :FAULT
IF NOT EXIST REGISTER.FRM GOTO :FAULT
IF NOT EXIST SNAPSHOT.COM GOTO :FAULT
IF NOT EXIST CHOOSE.COM GOTO :FAULT
IF NOT EXIST MM_INTR.SDX GOTO :FAULT
IF NOT EXIST MM_UREG.SDX GOTO :FAULT
IF NOT EXIST MM_DEM1.SDX GOTO :FAULT
IF NOT EXIST MM_DEM2.SDX GOTO :FAULT
IF NOT EXIST MM_DEM3.SDX GOTO :FAULT
IF NOT EXIST DSKMSG.SDX GOTO :FAULT
IF NOT EXIST DSKMSG.MUX GOTO :FAULT
IF NOT EXIST DSKMSG.COM GOTO :FAULT
IF     EXIST DSKMSG.TXT GOTO :MAIN_MENU
:FAULT
CLS
PROMPT $G
ECHO ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
ECHO +                                                            +
ECHO +  The files included in your SNAPSHOT package are required  +
ECHO +  to run MENU.BAT, but they were not found  in the current  +
ECHO +  drive/directory and the batch cannot be run.              +
ECHO +                                                            +
ECHO +  Switch to the drive/directory with the  SNAPSHOT  files,  +
ECHO +  and try again.                                            +
ECHO +                                                            +
ECHO ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
PROMPT $P$G
GOTO :END

:MAIN_MENU
CLS
CHOOSE WELCOME TO SNAPSHOT^{I}ntroduction^{P}rint Manual^{R}egistration^{E}xtra Programs^{D}emo, Installation, and Exit
IF ERRORLEVEL=5 GOTO :MM_INTRO
IF ERRORLEVEL=4 GOTO :MM_PRINT
IF ERRORLEVEL=3 GOTO :MM_REGISTER
IF ERRORLEVEL=2 GOTO :EXTRA
IF ERRORLEVEL=1 GOTO :MM_DEMO
GOTO :MAIN_MENU


:MM_INTRO -- "Introduction" SELECTION
CLS
TYPE MM_INTR.SDX
PAUSE
GOTO :MAIN_MENU


:MM_PRINT -- "Print Manual" SELECTION
CLS
ECHO PRINTING MANUAL TEXT
COPY MANUAL.TXT PRN
GOTO :MAIN_MENU


:MM_REGISTER -- "Registration" SELECTION
CLS
TYPE MM_UREG.SDX
PAUSE
CLS
CHOOSE PRINT REGISTRATION FORM?^{Y}es^{N}o
IF ERRORLEVEL=2 GOTO :MM_REG_PNT
GOTO :MAIN_MENU
:MM_REG_PNT
CLS
ECHO PRINTING REGISTRATION FORM
COPY REGISTER.FRM PRN
GOTO :MAIN_MENU


:EXTRA -- "Extra Programs" SUB-MENU
CLS
TYPE DSKMSG.SDX
PAUSE
:EXT_MENU
CLS
CHOOSE DSKMSG.MUX
IF ERRORLEVEL=5 GOTO :EXT_ABOUT
IF ERRORLEVEL=4 GOTO :EXT_PROMPT
IF ERRORLEVEL=3 GOTO :EXT_CMDLINE
IF ERRORLEVEL=2 GOTO :EXT_FILE
IF ERRORLEVEL=1 GOTO :MAIN_MENU
GOTO :MAIN_MENU

:EXT_ABOUT -- "Extra"/"About" SELECTION
DSKMSG
GOTO :EXT_MENU

:EXT_PROMPT -- "Extra"/"Text via Prompt" SELECTION
ECHO Enter the text of a message that you
ECHO wish to display using DESK MESSAGE.
DSKMSG BKG=BLACK PROMPT
IF ERRORLEVEL=9 GOTO :EXT_PAUSE
GOTO :EXT_MENU

:EXT_CMDLINE -- "Extra"/"Text via Command Line" SELECTION
DSKMSG TEXT=BACK AT NOON...
IF ERRORLEVEL=9 GOTO :EXT_PAUSE
GOTO :EXT_MENU

:EXT_FILE -- "Extra"/"Text via File" SELECTION
DSKMSG FILE=DSKMSG.TXT
IF ERRORLEVEL=1 GOTO :EXT_PAUSE
GOTO :EXT_MENU

:EXT_PAUSE
PAUSE
GOTO :EXT_MENU


:MM_DEMO -- "Install to Drive-C" SELECTION
CLS
TYPE MM_DEM1.SDX
CHOOSE {BWC}COPY SNAPSHOT.COM C:\^{Y}es -- Continue with Installation & Demo^{N}o -- Exit to DOS
IF ERRORLEVEL=2 GOTO :MM_INS_SNAP
CLS
GOTO :END
:MM_INS_SNAP
CLS
ECHO Copying SNAPSHOT to the root directory of Drive-C.
PROMPT $G
ECHO ON
COPY SNAPSHOT.COM C:\
ECHO OFF
CLS
ECHO Loading the SNAPSHOT TSR specifying a trigger key combination of CTRL+ALT
ECHO and three concurrent snapshots of up to 2000 bytes (full screen) each.
ECHO ON
C:\SNAPSHOT CTRL+ALT 3 2000
ECHO OFF
PROMPT $P$G
PAUSE

CLS
TYPE MM_DEM2.SDX
PAUSE

CLS
TYPE MM_DEM3.SDX
PAUSE

CLS
TYPE MM_DEM4.SDX

:END