ECHO OFF
CLS
REM -- Test for access to all required files
IF NOT EXIST MANUAL.TXT GOTO :FAULT
IF NOT EXIST REGISTER.FRM GOTO :FAULT
IF NOT EXIST CHOOSE.COM GOTO :FAULT
IF NOT EXIST MAIN.MUX GOTO :FAULT
IF NOT EXIST MM_INT.SDX GOTO :FAULT
IF NOT EXIST MM_SEL.SDX GOTO :FAULT
IF NOT EXIST MM_BRA.SDX GOTO :FAULT
IF NOT EXIST MM_REG.SDX GOTO :FAULT
IF NOT EXIST MM_INS.SDX GOTO :FAULT
IF NOT EXIST MM_WST.SDX GOTO :FAULT
IF NOT EXIST DSP_SPEC.SDX GOTO :FAULT
IF NOT EXIST DSP_TEXT.SDX GOTO :FAULT
IF NOT EXIST DSP_COLO.SDX GOTO :FAULT
IF NOT EXIST DSKMSG.MUX GOTO :FAULT
IF NOT EXIST DSKMSG.COM GOTO :FAULT
IF NOT EXIST DSKMSG.SDX GOTO :FAULT
IF     EXIST DSKMSG.TXT GOTO :MAIN_MENU
:FAULT
CLS
PROMPT $G
ECHO ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
ECHO +                                                            +
ECHO +  The files included in your  CHOOSE  package are required  +
ECHO +  to run MENU.BAT, but they were not found  in the current  +
ECHO +  drive/directory and the batch cannot be run.              +
ECHO +                                                            +
ECHO +  Switch to the drive/directory with the CHOOSE files, and  +
ECHO +  try again.                                                +
ECHO +                                                            +
ECHO ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
PROMPT $P$G
GOTO :END

:MAIN_MENU
CLS
CHOOSE MAIN.MUX
IF ERRORLEVEL=10 GOTO :MM_INT
IF ERRORLEVEL=9 GOTO :MM_DSP
IF ERRORLEVEL=8 GOTO :MM_SEL
IF ERRORLEVEL=7 GOTO :MM_BRA
IF ERRORLEVEL=6 GOTO :MM_REG
IF ERRORLEVEL=5 GOTO :MM_MAN
IF ERRORLEVEL=4 GOTO :MM_INS
IF ERRORLEVEL=3 GOTO :MM_WST
IF ERRORLEVEL=2 GOTO :EXTRA
IF ERRORLEVEL=1 GOTO :END
GOTO :END

:MM_INT -- "Introduction" SELECTION
CLS
TYPE MM_INT.SDX
PAUSE
GOTO :MAIN_MENU

:MM_DSP -- "Menu Display" SUB-MENU
CLS
CHOOSE {WCB}MENU DISPLAY^Menu {S}pecification^Special ({003}) & Highlighted Menu {T}ext^Menu {C}olors^{M}ain Menu
IF ERRORLEVEL=4 GOTO :DSP_SPEC
IF ERRORLEVEL=3 GOTO :DSP_TEXT
IF ERRORLEVEL=2 GOTO :DSP_COLO
IF ERRORLEVEL=1 GOTO :MAIN_MENU
GOTO :MAIN_MENU

:DSP_SPEC -- "Menu Display"/"Menu Specification" SELECTION
TYPE DSP_SPEC.SDX
PAUSE
GOTO :MM_DSP

:DSP_TEXT -- "Menu Display"/"Special & Highlighted Menu Text" SELECTION
TYPE DSP_TEXT.SDX
PAUSE
GOTO :MM_DSP

:DSP_COLO -- "Menu Display"/"Menu Colors" SELECTION
TYPE DSP_COLO.SDX
PAUSE
GOTO :MM_DSP

:MM_SEL -- "Menu Selection" SELECTION
CLS
TYPE MM_SEL.SDX
PAUSE
GOTO :MAIN_MENU

:MM_BRA -- "Batch Branching" SELECTION
CLS
TYPE MM_BRA.SDX
PAUSE
GOTO :MAIN_MENU

:MM_REG -- "User Registration" SELECTION
CLS
TYPE MM_REG.SDX
PAUSE
CLS
CHOOSE PRINT REGISTRATION FORM?^{007} {Y}es^{007} {N}o
IF ERRORLEVEL=2 GOTO :MM_REG_PNT
GOTO :MAIN_MENU
:MM_REG_PNT
CLS
ECHO PRINTING REGISTRATION FORM
COPY REGISTER.FRM PRN
GOTO :MAIN_MENU

:MM_MAN -- "Print Manual" SELECTION
CLS
ECHO PRINTING MANUAL TEXT
COPY MANUAL.TXT PRN
GOTO :MAIN_MENU

:MM_INS -- "Install to Drive-C" SELECTION
CLS
TYPE MM_INS.SDX
CHOOSE {BWC}COPY CHOOSE.COM C:\^{007} {Y}es^{007} {N}o
IF ERRORLEVEL=2 GOTO :MM_INS_CPY
GOTO :MAIN_MENU
:MM_INS_CPY
CLS
ECHO Copying CHOOSE to the root directory of Drive-C.
ECHO ON
COPY CHOOSE.COM C:\
ECHO OFF
PAUSE
GOTO :MAIN_MENU

:MM_WST -- "Warm start" SELECTION
CLS
TYPE MM_WST.SDX
CHOOSE {WWR}CONFIRM SYSTEM RE-BOOT^Yes^No
CLS
IF ERRORLEVEL=2 GOTO :RE-BOOT
GOTO :MAIN_MENU
:RE-BOOT
CHOOSE RE-BOOT

:EXTRA -- "Extra" SUB-MENU
CLS
TYPE DSKMSG.SDX
PAUSE
:EXT_MENU
CLS
CHOOSE DSKMSG.MUX
IF ERRORLEVEL=5 GOTO :EXT_ABOUT
IF ERRORLEVEL=4 GOTO :EXT_PROMPT
IF ERRORLEVEL=3 GOTO :EXT_CMDLINE
IF ERRORLEVEL=2 GOTO :EXT_FILE
IF ERRORLEVEL=1 GOTO :MAIN_MENU
GOTO :MAIN_MENU

:EXT_ABOUT -- "Extra"/"About" SELECTION
DSKMSG
GOTO :EXT_MENU

:EXT_PROMPT -- "Extra"/"Text via Prompt" SELECTION
ECHO Enter the text of a message that you
ECHO wish to display using DESK MESSAGE.
DSKMSG BKG=BLACK PROMPT
IF ERRORLEVEL=9 GOTO :EXT_PAUSE
GOTO :EXT_MENU

:EXT_CMDLINE -- "Extra"/"Text via Command Line" SELECTION
DSKMSG TEXT=BACK AT NOON...
IF ERRORLEVEL=9 GOTO :EXT_PAUSE
GOTO :EXT_MENU

:EXT_FILE -- "Extra"/"Text via File" SELECTION
DSKMSG FILE=DSKMSG.TXT
IF ERRORLEVEL=1 GOTO :EXT_PAUSE
GOTO :EXT_MENU

:EXT_PAUSE
PAUSE
GOTO :EXT_MENU

:END