/*
**  $VER: $Id: PZ_MakeContact.rexx,v 5.0 1993/11/12 01:15:46 chris Exp $
**  Copyright (C) 1992, 1993 by Christian A. Weber, Zürich, Switzerland.
**
**  Creates a big picture out of some small ones which must be in
**  T:__contacts/ and have numbers from 0 as names.
**
**  You may wish to change MAXMEM for ADPro if you don't have enough RAM,
**  and the delay after loading if you have a slow HD :)
*/

options results
arg adprodir numx numy sizex sizey destname
address 'ADPro'


/*
** Space between two pictures in pixels
*/
XSPACING=16
YSPACING=16

sizex = sizex + XSPACING
sizey = sizey + YSPACING


/*
** Make sure ADPro is running
*/
IF ~show(ports,'ADPro') THEN
DO
  Address COMMAND 'C:Assign ADPRO: '||adprodir
  Address COMMAND 'Run >NIL: ADPRO:ADPro MAXMEM=5000000 BEHIND'
  Address COMMAND 'C:Wait 5'
  IF ~show(ports,'ADPro') THEN EXIT
END


/*
** Screen types for ADPro
*/
LORES     = 0
HIRES     = 1
LACE      = 2
PAL       = 4
XOVERSCAN = 8
YOVERSCAN = 16

HIRESBIT  = 0
LACEBIT   = 1


/*
** Now create the background picture ...
*/
SCREEN_TYPE  HIRES+LACE
LFORMAT    'BACKDROP'
LOAD    dummy numx*sizex+XSPACING numy*sizey+YSPACING COLOR 255 128 220
OPERATOR  RECTANGLE 0 0 numx*sizex+XSPACING numy*sizey+YSPACING 5 200 30 80 100

/*
** Load the small images
*/

do y=0 to numy-1

  do x=0 to numx-1

    LFORMAT 'UNIVERSAL'
    LOAD    'T:__contact/' || numx*y+x XSPACING+x*sizex YSPACING+y*sizey 100 0 0 0
  end
end


/*
** Now save the image
*/
SFORMAT 'JPEG'
SAVE    destname IMAGE 50