; $VER: Installer script for RAWInfo 1.2 (09.03.00) © 1999/2000 by Stephan Rupprecht

;--- localize strings ----
(if (= @language "deutsch")
(
	(set #wrongver "RAWBInfo benötigt mindestens AmigaOS3.5.\nInstallation kann nicht durchgeführt werden.")
	(set #askdir_prompt "Bitte wählen Sie das Zielverzeichnis für den RAWBInfo")
	(set #nocatalog "Keinen deutschen Katalog gefunden!?")
)
(
	;--- spanish strings (13.2.00) by © 2000 Dámaso D. Estévez <amidde@arrakis.es>
	(if (= @language "espańol")
	(
		(set #wrongver "RAWBInfo requiere al menos la versión 3.5 del S.O.\nInstalación abortada.")
		(set #askdir_prompt "Por favor, elija el cajón donde debe ser instalado RAWBInfo")
		(set #nocatalog "Lo siento, pero el catálogo espańol ˇno está disponible en este momento!")
	)
	(
		(set #wrongver "RAWBInfo requires at least AmigaOS3.5\nInstallation aborted.")
		(set #askdir_prompt "Please select the drawer where RAWBInfo should be installed")
		(set #nocatalog "")
	)
	)
)
)

;--- check os version ---
(set #vernum (getversion "workbench.library" (resident)))
(set #vernum (/ #vernum 65536))

(if(< #vernum 44)
	(abort #wrongver)
)

;--- copy main program ---
(set @default-dest
	(askdir
		(prompt #askdir_prompt)
		(help @askdir-help)
		(default "SYS:WBStartup")
	)
)

(copyfiles
	(help @copyfiles-help)
	(source "RAWBInfo")
	(dest @default-dest)
)

;--- copy .info file if neccessary ---
(set #info_path (tackon @default-dest "RAWBInfo.info") )

(if (not (exists #info_path) )
	(copyfiles
		(help @copyfiles-help)
		(source "RAWBInfo.info")
		(dest @default-dest)
	)
)

;--- copy catalog ---
(if (<> @language "english")
(
	(set #src_name
		(tackon "Catalogs/" @language)
	)

	(set #dst_name
		(tackon "LOCALE:" #src_name)
	)

	(set #src_name
		(tackon #src_name "rawbinfo.catalog")
	)

	(if (exists #src_name (noreq))
	(
		(copyfiles
			(help @copyfiles-help)
			(source #src_name)
			(dest #dst_name)
		)
	)
		(message "Sorry, there's no "@language" catalog available")
	) 
)
)

;--- eof ---