; Install script for ReqTools (Workbench 2.0)

(set @default-dest "")

(set reqtoolslib "/libs/reqtools.library")
(set rtpatch "/RTPatch/RTPatch")

;=============================================================================
; English strings

(set #bad-kick
(cat "You must be using Kickstart 2.04 to install using this script."
	  " Double-click the 'Workbench_1.2-1.3' icon to install ReqTools on"
	  " Kickstart 1.2 or 1.3 machines."
))

(set #copying-reqtools "Copying reqtools.library to Libs:...")
(set #copying-rtpatch  "Copying RTPatch...")

(set #install-msg
(cat "\n\nReqTools installation script.\n"
     "This script installs ReqTools library on your Amiga.\n\n"
     "Read the DISTRIBUTION file for\n"
     "more information on the distribution\n"
     "and commercial usage of ReqTools.\n\n"
     "ReqTools © 1991-1994 Nico François\n"
     "           1995-1996 Magnus Holmgren\n"
     "All rights reserved."
))

;=============================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
(
    (abort #bad-kick)
))

;=============================================================================

(message #install-msg)

(copylib
	(prompt "\n" #copying-reqtools)
	(help @copylib-help)
	(source reqtoolslib)
	(dest "Libs:")
	(confirm)
)

(if (exists "C:RTPatch")
(
	(copylib
		(prompt "\n" #copying-rtpatch)
		(help @copylib-help)
		(source rtpatch)
		(dest "C:")
		(confirm)
	)
))

(if (exists "SYS:WbStartup/RTPatch")
(
	(copylib
		(prompt "\n" #copying-rtpatch)
		(help @copylib-help)
		(source rtpatch)
		(dest "SYS:WbStartup")
		(confirm)
	)
))