; $VER: ICS 1.09 (29.02.00)
; Copyright (C)1999-2000 Wolf Faust

(complete 0)
(delopts "oknodelete" "force" "askuser")

(set icsvernew 2)  ; Set to the version/revision of ICS library!!!
(set icsrevnew 9)

;**** English text
;-------
(set #welcome-pirate
(cat "\nWelcome to the ICS for Scanners.\n\n"
	"ICS is Copyright (C)1999 by Wolf Faust\n\n"
))
;-------
(set #waitmsg
(cat "\n\n\n\nWorking. Please wait..."
))
(set #register
(cat "\nPlease remember:\nYou can use ICS for free as long as you return the registration form within 48 hours after start using ICS\n"
))
;-------
(set #bad-kick
(cat	"\nYour system software is very old. "
	"You must use at least Kickstart 2.04 for all ICS programs."
))
;--------------
(set #foundicsver
(cat "\nI found an exisiting ICS installation\n(Library Ver. %ld Rev. %ld).\nPlease select the type of action you want to perform:\n"
))
(set #foundics
(cat "I found an exisiting ICS installation. Please select the type of action you want to perform:"
))
(set #foundicshelp
(cat "When selecting update, the ICS software will be updated in the ICS: location found.\n\n"
	"When selecting complete installation, you will continue to do a complete ICS installation.\n\n"
	@askoptions-help
))
(set #foundics-choices0
(cat "Remove ICS from your system"
))
(set #foundics-choices1
(cat "Update existing ICS software"
))
(set #foundics-choices2
(cat "Do a complete new ICS installation"
))

(set #yes
(cat "YES"
))
(set #yesupdate
(cat "Yes, overwrite"
))
(set #nodrawer
(cat "No, continue"
))
;--------------
(set #ask-ics
(cat "Select the disk or drawer the 'ICS' application drawer should be created in?"
))
(set #ask-ics-help
(cat "\nThis section lets you choose in which drawer or on which disk the "
	"ICS programs should be installed. "
	"The program can be installed to any disk/drawer you like. "
	"The selected disk should have at least 3 MByte free space.\n\n"
	@askdir-help
))
;--------------
(set #abortunpack
(cat "\nError occured while running the installation decompression program. "
	"The error occured during decompressing of the file:\n\n\"%s\"\n\n"
))
;--------------
(set #cputype
(cat "\nPlease select for what type of CPU/FPU hardware ICS should be installed for.\n"
))
(set #cputype-help
(cat "\nICS was written for various CPU's (Central Processor Unit) supported by the Amiga OS. "
	"For instance, if you own a normal Amiga 4000 choose the 68040 FPU ICS library (FPU=Floating Point Unit).\n"
	"Older Amigas like the A500, A600, A1000, A2000 were build with the 68000 CPU.\n"
	"The Amiga 1200 has a 68020 CPU (no FPU!).\n"
	"The Amiga 3000(T) has a 68030 with FPU\n"
	"If your Amiga has accelerator board fitted, please choose the correct "
	"library.\n\nThere can be major speed differences between different versions of the library!!!\n"
	"Note: the 68000 version works with all Amigas but is the slowest.\n\n"
	@askoptions-help
))
;--------------
(set #userstartup
(cat "Can I add/remove an ICS: and ICS_Profiles: assign to/from your user-startup sequence?" 
))
;--------------
(set #foundnewerics
(cat "A newer ICS library Ver. %ld Rev. %ld is already installed on your system. Shall I install the Ver. %ld Rev. %ld library? Select NO to use the already installed library.\n"
))
(set #foundnewhelp
(cat "When selecting yes, the ICS library stored in LIBS: will be overwritten.\n\n"
	"When selecting no, the ICS programs will be installed and use the existing library.\n\n"
))
;--------------
(set #icsremoved
(cat "\nICS was removed from your system.\nYou may now delete the ICS drawer from your system.\n"
))
;--------------
(set #manual
(cat "manualE"
))
;--------------
(set #manualpath
(cat "Pages"
))
;--------------
(set #warnfpu
(cat "\nThis is just a note and NOT an error message:\n\n"
	"Make sure that your system has a correctly working "
	"680x0.library installed. Otherwise FPU errors can "
	"cause ICS to generate faulty/random images. "
	"Especialy older PowerPC board owners might need "
	"to update their system before their FPU is working correctly.\n"
	"\nYou can always install the slower 68000 version in order to "
	"avoid the rare CPU/FPU problems. But first go ahead with the FPU version..."
))


;*** German
(if (= @language "deutsch")
(
	(set #welcome-pirate
	(cat "\nWillkommen zur Installation der ICS Software!\n\n"
		"Copyright (C)1999 Wolf Faust\n\n"
	))
	;-------
	(set #waitmsg
	(cat "\n\n\n\nIch arbeite! Bitte warten..."
	))
	;-------
	(set #register
	(cat "\nNicht vergessen:\nSie können ICS kostenlos benutzen, solange Sie binnen 48 Stunden nach der ersten Nutzung die Software kostenlos registrieren."
	))
	;-------
	(set #bad-kick
	(cat	"\nIhre System-Software ist sehr alt. "
		"Sie brauchen mindestens Kickstart 2.04 für alle ICS-Programme."
	))
	;--------------
	(set #foundicsver
	(cat "\nIch habe eine installierte ICS Software gefunden\n(Library Ver. %ld Rev. %ld).\nBitte wählen Sie eine gewünschte Aktion:\n"
	))
	(set #foundics
	(cat "\nIch habe eine installierte ICS Software gefunden. Bitte wählen Sie eine gewünschte Aktion:\n"
	))
	(set #foundicshelp
	(cat "Wählen Sie entfernen, und die ICS Library sowie Assigns in S:User-Startup werden entfernt.\n\n"
		"Wählen Sie erneuern, dann wird die ICS Software in der ICS: Schublade upgedated.\n\n"
		"Wählen Sie komplette Installation, können Sie mit der normalen ICS Installation fortfahren.\n\n"
		@askoptions-help
	))
	(set #foundics-choices0
	(cat "ICS aus dem System entfernen"
	))
	(set #foundics-choices1
	(cat "Vorhandene ICS Software erneuern"
	))
	(set #foundics-choices2
	(cat "ICS komplett neu installieren"
	))
	(set #yes
	(cat "JA"
	))
	(set #yesupdate
	(cat "Ja, überschreiben"
	))
	(set #nodrawer
	(cat "Nein, weiter"
	))
	;--------------
	(set #ask-ics
	(cat "\nWählen Sie eine Disk/Verzeichnis, in dem das ICS-Verzeichnis angelegt werden soll."
	))
	(set #ask-ics-help
	(cat "\nIn diesem Teil können Sie wählen, auf welche Disk oder in welcher "
		"Schublade die ICS-Schublade mit den Programmen kopiert werden soll. Normalerweise sollten "
		"Sie hierzu die Schublade wählen, in der Sie auch Ihre anderen "
		"Grafikprogramme speichern. Die gewählte Disk sollte mindestens 3 MByte "
		"an freien Speicherplatz besitzen.\n\n"
		@askdir-help
	))
	;--------------
	(set #abortunpack
	(cat "\nEin Fehler trat beim Entpacken/Schreiben einer Datei auf!\n"
		"Das zu entpackende Archiv lautete:\n\n\"%s\"\n\n"
	))
	;--------------
	(set #cputype
	(cat "\nBitte wählen Sie, für welchen Prozessor ICS installiert werden soll.\n"
	))
	(set #cputype-help
	(cat "\nICS wurde für verschiedene Prozessoren erstellt. Bitte wählen Sie den Prozessor (CPU) "
		"und falls vorhanden, die Fließkomma-Einheit (FPU) Ihrer Hardware. "
		"Sollten Sie Ihren Amiga nicht mit einem schnelleren Prozessor erweitert haben, "
		"finden Sie folgende Prozessoren in Ihren Amiga:\n"
		"Amiga 500, 600, 1200, 2000:  CPU 68000\n"
		"Amiga 1200:     CPU 68020 ohne FPU\n"
		"Amiga 3000 (T): CPU 68030 mit FPU\n"
		"Amiga 4000:     CPU 68040 mit FPU\n\n"
		"Die ICS Geschwindigkeitsunterschiede können zwischen den verschiedenen CPU Versionen enorm sein.\n\n"
		@askoptions-help
	))
	;--------------
	(set #userstartup
	(cat "Kann ich einen ICS: und ICS_Profiles: Verweis in Ihrer User-Startup-Sequenz hinzufügen oder löschen?" 
	))
	;--------------
	(set #foundnewerics
	(cat "Eine neuere Version %ld Revision %ld der 'ics.ibrary' ist bereits auf Ihrem System installiert.\nSoll ich trotzdem die Ver. %ld Rev. %ld der Library installieren?\nWählen Sie Nein um die vorhandene Library zu benutzen.\n"
	))
	(set #foundnewhelp
	(cat "Wählen Sie ja, dann wird die 'ics.library' in der LIBS: Schublade mit einer älteren Version überschrieben.\n\n"
		"Wählen Sie Nein, werden die ICS Programme installiert, wobei die schon installierte 'ics.library' benutzt wird.\n\n"
	))
	;--------------
	(set #icsremoved
	(cat "\nICS wurde von Ihrem System entfernt.\nSie können jetzt die ICS Schublade löschen.\n"
	))
	;--------------
	(set #manual
	(cat "manual"
	))
	;--------------
	(set #manualpath
	(cat "Seiten"
	))
	;--------------
	(set #warnfpu
	(cat "\nDies ist ein Hinweis und keine Fehlermeldung:\n\n"
		"Damit die FPU-Version von ICS korrekt funktioniert, "
		"muß eine korrekt funktionierende 680x0.library in "
		"Ihrem System installiert sein. Besonders Besitzer "
		"älterer Systemsoftware sollten bei Fehlern in Bildern "
		"Ihr System updaten."
		"\n\nSollten die seltenen CPU/FPU Probleme auftauchen, "
		"können Sie bis zum Systemupdate die langsamere 68000er Version "
		"von ICS ausprobieren."
		"\nAber jetzt erst mal weiter... "
	))
))

(procedure Meter
(
	(set accum	(+ accum addmeter))
	(complete (/ (* accum 100) total))
))

(complete 0)
; (message #welcome-pirate)
(working #waitmsg)
(set @default-dest "")

(set total		100)
(set accum		0)
(set addmeter		0)
(set firstdisk "")
(set studiodefault "Default_Setting")
; **** sure we are running under a 2.04 or higher ROM???
(if (< (/ (getversion) 65536) 37)
	(abort #bad-kick)
)

(set icsvervalid 0)
(set icsver 0)
(set icsrev 0)
(if (= (exists "LIBS:ics.library") 1)
(
	(set vernum (getversion "LIBS:ics.library"))
	(set icsver (/ vernum 65536))
	(set icsrev (- vernum (* icsver 65536) ) )
	(if (OR (<> icsver 0) (<> icsrev 0))
	(
		(set icsvervalid 1)
	))
))
(set addmeter	10)
(Meter)
(set guessdrawer "")
(if (= guessdrawer "")
(
	(set guessdrawer (getassign "WORK" "d"))
	(if (= guessdrawer "")
	(
		(set guessdrawer (getassign "DH0" "d"))
		(if (= guessdrawer "")
		(
			(set guessdrawer (getassign "DH2" "d"))
			(if (= guessdrawer "")
			(
				(set guessdrawer "SYS:")
			))
		))
	))
))

(set inschoice 2)
(set icsassign "")
(set proassign "")
(set icsguessdrawer (getassign "ICS" "a"))
(if (<> icsguessdrawer "")
(
	(set proguessdrawer (getassign "ICS_Profiles" "a"))
	(if (<> proguessdrawer "")
	(
		(set icsassign "ICS:/")
		(set proassign "ICS_Profiles:/")
		(set icspath (expandpath "ICS:"))
		(set propath (expandpath "ICS_Profiles:"))

		(if (<> icsvervalid 0)
		(
			(set inschoice (askchoice (prompt (#foundicsver icsver icsrev))
				(help #foundicshelp)
				(choices #foundics-choices0 #foundics-choices1 #foundics-choices2)
				(default 1)
				)
			)
		)
		(
			(set inschoice (askchoice (prompt #foundics)
				(help #foundicshelp)
				(choices #foundics-choices0 #foundics-choices1 #foundics-choices2)
				(default 1)
				)
			)
		))
	))
))
(working #waitmsg)
(set addmeter	10)
(Meter)

(if (= inschoice 0)
(
	(set n 0)
	(while (set thisfile (select n  "LIBS:ics.library"
		"ENV:sys/ICSConvert_def_project.info"
		"ENVARC:sys/ICSConvert_def_project.info"
		"ENV:sys/ScanTarget_def_project.info"
		"ENVARC:sys/ScanTarget_def_project.info"
		"ENV:sys/ICS_def_project.info"
		"ENVARC:sys/ICS_def_project.info"
		"LOCALE:catalogs/deutsch/ICS_Library.catalog"
		"LOCALE:catalogs/deutsch/ICS_Convert.catalog"
		"LOCALE:catalogs/deutsch/ICS_ScanTarget.catalog"
		"ENV:ICS.prefs"
		"ENVARC:ICS.prefs"
		"" ))
	(
		(set n (+ n 1))
		(if (exists thisfile)
		(
			(delete thisfile)
		))
	))
	(set addmeter	20)
	(makeassign "ICS")
	(makeassign "ICS_Profiles")
	(set addmeter	20)
	(startup "ICS"
		(prompt (#userstartup))
		(help @startup-help)
	)
	(set addmeter	35)
	(message (#icsremoved))
	(exit (quiet))
)
(
	(set asknewver 0)
	(if (<> icsvervalid 0)
	(
		(if (> icsver icsvernew)
		(
			(set asknewver 1)
		)
		(
			(if (= icsver icsvernew)
			(
				(if (> icsrev icsrevnew)
				(
					(set asknewver 1)
				))
			))
		))
		(if (<> asknewver 0)
		(
			(if (askbool (prompt (#foundnewerics icsver icsrev icsvernew icsrevnew))
				(choices #yesupdate #nodrawer)
				(help (#foundnewhelp ))
				(default 0))
			(
				(set asknewver 0)
			))
		))
	
	))
	(set addmeter	5)
	(Meter)
	
	(if (= inschoice 2)
	(
		(set icsassign (askdir (prompt #ask-ics)
			(default guessdrawer)
			(help #ask-ics-help))
		)
		(set proassign (tackon icsassign "ICS"))
		(set icspath proassign) 
		(set propath (tackon proassign "ICS_Profiles"))
		(if (= (exists "ENV:ICS.prefs") 1)
		(
			(delete "ENV:ICS.prefs")
		))
		(if (= (exists "ENVARC:ICS.prefs") 1)
		(
			(delete "ENVARC:ICS.prefs")
		))
		(message #register)
	))
	(working #waitmsg)
	(set addmeter	5)
	(Meter)
	(set deflibtype 0)
	(set CPUStr (database "cpu"))
	(set FPUStr (database "fpu"))
	(if (OR (= CPUStr "68000") (= CPUStr "68010"))
		(set deflibtype	0)
	)
	(if (OR (= CPUStr "68020") (= CPUStr "68030"))
	(
		(set deflibtype	2)
		(if (= FPUStr "NOFPU")
			(set deflibtype	1)
		)
	))
	(if (OR (= CPUStr "68040") (= CPUStr "68060"))
	(
		(set deflibtype	3)
		(if (= FPUStr "NOFPU")
			(set deflibtype	1)
		)
	))
	(set libtype  (askchoice (prompt #cputype)
		(help #cputype-help)
		(choices "CPU 68000/10"             ;0
		         "CPU 68020/30/40"          ;1
		         "CPU 68020/30 + FPU"       ;2
		         "CPU 68040/60 + FPU"       ;3
		)
		(default deflibtype)
	))
	(set libname (select libtype  "Software/lib000.lzh"   ;0
		"Software/lib020.lzh"                         ;1
		"Software/lib030fpu.lzh"                      ;2
		"Software/lib040.lzh"                         ;3
	))

	(if (= inschoice 2)
	(
		(if (> libtype 2)
		(
			(message #warnfpu)
		))
	))

	
	(set addmeter	5)
	(Meter)
	(working #waitmsg)
	(copyfiles (source "lx")
		(dest "T:")
		(nogauge)
	)
	
	(makeassign "ICSPARENT" icsassign)
	(set exerr (run (cat "T:lx x Software/ics.lzh \"ICSPARENT:\"")))
	(if (> exerr 0)
	(
		(abort (#abortunpack "Software/ics.lzh"))
	))
	
	(set addmeter	15)
	(Meter)
	(makeassign "PROPARENT" proassign)
	(set exerr (run (cat "T:lx x Software/profiles.lzh \"PROPARENT:\"")))
	(if (> exerr 0)
	(
		(abort (#abortunpack "Software/profiles.lzh"))
	))
	
	(set addmeter	10)
	(Meter)
	(if (= asknewver 0) ; Are we allowed to install the library?
	(
		(set exerr (run (cat "T:lx x " libname " \"LIBS:\"")))
		(if (> exerr 0)
		(
			(abort (#abortunpack libname))
		))
	))

	(set addmeter	5)
	(Meter)
	(if (OR (= inschoice 2) (<> (exists "ENVARC:sys/ICSConvert_def_project.info") 1) ) ; Update default icon if not already available....
	(
		(copyfiles (source "Software/ICSConvert_def_project.info")
			(dest "ENVARC:sys")
			(nogauge)
		)
		(copyfiles (source "Software/ICSConvert_def_project.info")
			(dest "ENV:sys")
			(nogauge)
		)
	))

	(set addmeter	5)
	(Meter)

	(if (OR (= inschoice 2) (<> (exists "ENVARC:sys/ScanTarget_def_project.info") 1) ) ; Update default icon if not already available....
	(
		(copyfiles (source "Software/ScanTarget_def_project.info")
			(dest "ENVARC:sys")
			(nogauge)
		)
		(copyfiles (source "Software/ScanTarget_def_project.info")
			(dest "ENV:sys")
			(nogauge)
		)
	))


	(set addmeter	5)
	(Meter)
	(makeassign "ICS" icspath)
	(if (= (exists (cat "ICS:" #manualpath)) 2)
	(
		(set n 0)
		(while (< n 35)
		(
			(set n (+ n 1))
			(if (exists (cat "ICS:" #manualpath "/page." n))
			(
				(delete (cat "ICS:" #manualpath "/page." n ))
			))
			(if (exists (cat "ICS:" #manualpath "/page." n "L"))
			(
				(delete (cat "ICS:" #manualpath "/page." n "L"))
			))
		))
	))
	(set exerr (run (cat "T:lx x Software/" #manual ".lzh \"ICS:\"")))
	(if (> exerr 0)
	(
		(abort (#abortunpack (cat "Software/" #manual ".lzh")))
	))
	(if (= (exists (cat "Software/" #manual "L.lzh")) 1)
	(
		(set exerr (run (cat "T:lx x Software/" #manual "L.lzh \"ICS:\"")))
		(if (> exerr 0)
		(
			(abort (#abortunpack (cat "Software/" #manual "L.lzh")))
		))
	))
	(set addmeter	10)
	(Meter)

	(if (= inschoice 1) ; Update ?
	(
		(if (<> @language "deutsch")
		(
			(if (= (exists (cat "ICS:Seiten")) 2)
			(
				(set n 0)
				(while (< n 35)
				(
					(set n (+ n 1))
					(if (exists (cat "ICS:Seiten/page." n))
					(
						(delete (cat "ICS:Seiten/page." n ))
					))
					(if (exists (cat "ICS:Seiten/page." n "L"))
					(
						(delete (cat "ICS:Seiten/page." n "L"))
					))
				))

				(set exerr (run (cat "T:lx x Software/manual.lzh \"ICS:\"")))
				(if (> exerr 0)
				(
					(abort (#abortunpack (cat "Software/manual.lzh")))
				))
				(if (= (exists (cat "Software/manualL.lzh")) 1)
				(
					(set exerr (run (cat "T:lx x Software/manualL.lzh \"ICS:\"")))
					(if (> exerr 0)
					(
						(abort (#abortunpack (cat "Software/manualL.lzh")))
					))
				))
			))
		))
		(if (<> @language "english")
		(
			(if (= (exists (cat "ICS:Pages")) 2)
			(
				(set n 0)
				(while (< n 35)
				(
					(set n (+ n 1))
					(if (exists (cat "ICS:Pages/page." n))
					(
						(delete (cat "ICS:Pages/page." n ))
					))
					(if (exists (cat "ICS:Pages/page." n "L"))
					(
						(delete (cat "ICS:Pages/page." n "L"))
					))
				))
				(set exerr (run (cat "T:lx x Software/manualE.lzh \"ICS:\"")))
				(if (> exerr 0)
				(
					(abort (#abortunpack (cat "Software/manualE.lzh")))
				))
				(if (= (exists (cat "Software/manualEL.lzh")) 1)
				(
					(set exerr (run (cat "T:lx x Software/manualEL.lzh \"ICS:\"")))
					(if (> exerr 0)
					(
						(abort (#abortunpack (cat "Software/manualEL.lzh")))
					))
				))
			))
		))

	))

	(copyfiles (source "VER")
		(dest icspath)
		(nogauge)
	)

	(set addmeter	10)
	(Meter)
	(startup "ICS"
		(prompt (#userstartup))
		(help @startup-help)
		(command "Assign ICS: \"" icspath "\"\n"
			"Assign ICS_Profiles: \"" propath "\"\n"
	            )
	)

	(if (= (exists "LOCALE:catalogs/deutsch") 2)
	(
		(copyfiles (source (tackon icspath "catalogs/deutsch/ICS_Library.catalog"))
			(dest "LOCALE:catalogs/deutsch")
			(nogauge)
		)
		(copyfiles (source (tackon icspath "catalogs/deutsch/ICS_Convert.catalog"))
			(dest "LOCALE:catalogs/deutsch")
			(nogauge)
		)
		(copyfiles (source (tackon icspath "catalogs/deutsch/ICS_ScanTarget.catalog"))
			(dest "LOCALE:catalogs/deutsch")
			(nogauge)
		)
	))

	(makeassign "ICS" icspath)
	(makeassign "ICS_Profiles" propath)
	(makeassign "ICSPARENT")
	(makeassign "PROPARENT")
	(delete "t:lx")
	(set @default-dest icspath)
))

(complete 100)