; $VER: Install_BenchTrash 40.4 (28th February 1998)
; Script to install BenchTrash version 1.24 and up
; © 1997,98 THOR - Software
;
; The installer software is copyrighted © 1993 CBM
;

; tell the user that we're 0% done
(complete 0)

;=============================================================================
; useful procedure

(procedure TERMINATE (makeassign "..BenchTrash..")

)

;==========================================================================
; termination stuff

(onerror (TERMINATE))

;==========================================================================
; get current WB version
(set #version (/ (getversion "LIBS:version.library") 65536))

;get language specific strings
;==========================================================================
; English strings

(set default_lang 4)

(set #yes "Yes")
(set #no  "No")

(set #which-disk
(cat "Where should I install BenchTrash?"
))

(set #which-disk-help
(cat "This section lets you choose where the "
     "the BenchTrash program should go. It defaults to "
     "the SYS:WBStartup drawer so this program gets "
     "launched during booting.\n"
     "No drawer will be created.\n\n"
     @askdir-help
))

(set #move-old-1
(cat "Copy"
))

(set #move-old-2
(cat "Skip"
))


(set #bt-newicons
(cat "Shall I install the NewIcons version of BenchTrash?"
))

(set #bt-newicons-help
(cat "You may choose here to install a better looking NewIcons "
     "version of the BenchTrash icon. This requires, however, the "
     "newicons.library, but looks better for screens with more "
     "colors. Thanks to Claudio Pucci for drawing this icon."
))

(set #trash-newicons
(cat "Shall I install the NewIcons version of the Trashcan icon?"
))

(set #trash-newicons-help
(cat "You may choose here to install a better looking NewIcons "
     "version of the Trashcan icon, to replace the usual icon "
     "stored in Trashcan.info that comes with the workbench.\n"
     "This requires, however, the "
     "newicons.library, but looks better for screens with more "
     "colors. Thanks to Claudio Pucci for drawing this icon."
))

(set #do-locale
(cat    "Which languages do you want to install?"
))

(set #locale-help
(cat    "BenchTrash can be localized to various languages. "
        "Please select the languages you want to install."
        "English is built in, btw."
))

(set #copy-help
(cat    "O.K. to install the BenchTrash Guide?"
))

(set #copy-help-help
(cat    "The BenchTrash guide is a documentation of "
        "the BenchTrash program.\n"
        "If you aren't "
        "really low on disk space, you should install it."
))

(set #help-dir
(cat    "Please select the drawer to install the help-guide:"
))

(set #help-help
(cat    "BenchTrash comes with an online help guide, using Commodore's "
        "AmigaGuide or MultiView program. Please select the drawer to copy "
        "this database to."
))


(set #browser-where
(cat    "Please locate your favorite AmigaGuide browser:"
))

(set #browser-help
(cat    "Please select a program that can display AmigaGuide files. "
        "This should be AmigaGuide or Multiview. As a last resort, "
        "select MORE or Ed, that can be found in the Utilities or "
        "C: drawer of your workbench disk."
))

(set #copy-extras
(cat    "Shall I install the BenchTrash extras?"
))

(set #copy-extras-help
(cat    "The Extras programs can be used to unmount a volume "
        "by dragging its icon onto the benchtrash. They consist "
        "of one script and one tiny program.\n"
        "The script will be copied to the S: drawer and "
        "the command will go into C:.\n"
        "Please consult the ReadMe file in the Extras drawer "
        "in this archive on how to use them."
))


(set #exit-not-found
(cat    "Unable to find your file \"%s\" - DOS error %ld "
        "- installation aborted. "
))

(set #exit-text
(cat    "Installation of BenchTrash done. Hope you enjoy it..."
))

;==========================================================================
;say hi !
(welcome)

;==========================================================================
; now copy BenchTrash to target

(set #target    (askdir (prompt #which-disk)
                        (help   #which-disk-help)
                        (default "SYS:WBStartup")
                )
)

(set @default-dest #target)

(copyfiles
        (source "BenchTrash")
        (infos)
        (noposition)
        (dest #target)
)

;===========================================================================
;Install newicons ?
(complete 20)

(set #pi-bt-newicons
        (askbool        (prompt #bt-newicons)
                        (help #bt-newicons-help)
                        (default 0)
                        (choices #yes #no)
        )
)

(if #pi-bt-newicons
        (copyfiles
                (source "NewIcons/BenchTrash.info")
                (dest #target)
        )
)


(set #pi-trash-newicons
        (askbool        (prompt #trash-newicons)
                        (help #trash-newicons-help)
                        (default 0)
                        (choices #yes #no)
        )
)

(if #pi-trash-newicons
        (copyfiles
                (source "NewIcons/Trashcan.info")
                (dest "SYS:Trashcan.info")
        )
)

;==========================================================================
(complete 20)
;add language-specific if 2.1 or higher
(if (>= #version 38)
        ;then
        (
                (set #language (askoptions      (prompt #do-locale)
                                                (help #locale-help)
                                                (default -1)
                                                (choices "English"
                                                         "Deutsch"
                                                         "Italiano"
                                                         "Français"
                                                         "Greek"
                                                         "Svenska"
                                                         "suomi"
                                                         "Español"
                                                         "Norsk"
                                                         "ÃeÓtina"
                                                         "Português"
                                                         "Türkçe"
                                                )
                                )
                )

                (if (IN #language 1)
                        (if (exists "LOCALE:Catalogs/Deutsch")
                                (copyfiles
                                        (source "Deutsch/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Deutsch/")
                                )
                        )
                )

                (if (IN #language 2)
                        (if (exists "LOCALE:Catalogs/Italiano")
                                (copyfiles
                                        (source "Italiano/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Italiano/")
                                )
                        )
                )

                (if (IN #language 3)
                        (if (exists "LOCALE:Catalogs/Français")
                                (copyfiles
                                        (source "Français/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Français/")
                                )
                        )
                )

                (if (IN #language 4)
                        (if (exists "LOCALE:Catalogs/Greek")
                                (copyfiles
                                        (source "Greek/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Greek/")
                                )
                        )
                )

                (if (IN #language 5)
                        (if (exists "LOCALE:Catalogs/Svenska")
                                (copyfiles
                                        (source "Svenska/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Svenska/")
                                )
                        )
                )

                (if (IN #language 6)
                        (if (exists "LOCALE:Catalogs/Suomi")
                                (copyfiles
                                        (source "Suomi/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Suomi/")
                                )
                        )
                )

                (if (IN #language 7)
                        (if (exists "LOCALE:Catalogs/Español")
                                (copyfiles
                                        (source "Español/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Español/")
                                )
                        )
                )

                (if (IN #language 8)
                        (if (exists "LOCALE:Catalogs/Norsk")
                                (copyfiles
                                        (source "Norsk/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Norsk/")
                                )
                        )
                )

                (if (IN #language 9)
                        (if (exists "LOCALE:Catalogs/ÃeÓtina")
                                (copyfiles
                                        (source "ÃeÓtina/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/ÃeÓtina/")
                                )
                        )
                )


                (if (IN #language 10)
                        (if (exists "LOCALE:Catalogs/Português")
                                (copyfiles
                                        (source "Português/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Português/")
                                )
                        )
                )

                (if (IN #language 11)
                        (if (exists "LOCALE:Catalogs/Türkçe")
                                (copyfiles
                                        (source "Türkçe/BenchTrash.catalog")
                                        (dest   "LOCALE:Catalogs/Türkçe/")
                                )
                        )
                )

        )
)

(complete 40)
;===========================================================================
;ask user to install the BenchTrash-guide
(if (> @user-level 1)
        (set #do-help   (askbool        (prompt #copy-help)
                                        (help #copy-help-help)
                                        (default 1)
                                        (choices #yes #no)
                        )
        )
        (set #do-help 1)
)

(if #do-help
        (
                (set #where-guide       (askdir         (prompt #help-dir)
                                                        (help   #help-help)
                                                        (default "SYS:")
                                        )
                )

                (if #where-guide
                        (
                                (copyfiles
                                        (source "BenchTrash.Guide")
                                        (dest #where-guide)
                                )
                                (copyfiles
                                        (source "BenchTrash.Guide.info")
                                        (dest #where-guide)
                                )

                                (set #guide-path (askfile       (prompt #browser-where)
                                                                (help #browser-help)
                                                                (default "SYS:Utilities/MultiView")
                                                )
                                )

                                (if #guide-path
                                        (tooltype
                                                (dest (tackon #where-guide "BenchTrash.Guide"))
                                                (setdefaulttool #guide-path)
                                        )
                                )

                        )
                )
        )
)
;==========================================================================
(complete 80)
(if (> @user-level 1)
        (set #do-extras (askbool        (prompt #copy-extras)
                                        (help #copy-extras-help)
                                        (default 0)
                                        (choices #yes #no)
                        )
        )
        (set #do-extras 0)
)

(if #do-extras
        (
                (copyfiles      (source "Extras/ResolveDeviceName")
                                (dest   "C:")
                )

                (copyfiles      (source "Extras/RemoveDevice")
                                (dest   "S:")
                )
        )
)

;==========================================================================
(complete 100)

(TERMINATE)

(exit #exit-text)