; $VER: Install_SVLib V22.1 (16.11.98)
; © 1993-98 by Andreas R. Kleinert.
; This is the Installer Script for superview.library V22+
;
; Italian strings by Alessandro Basso <cralex@amiga.dei.unipd.it>
; Norwegian strings by Roger Hågensen <msi@sn.no>
; French strings by Julien Wilk <wilkj@esiee.fr>
; Spanish strings by Dámaso D. Estévez <amidde@arrakis.es>
;


; *** english is default language

    (set @app-name "SuperView-Library")
    (set #welc "SuperView-Library Installation")
    (set #mcp (cat "If you are running MCP and don't disable the\n"
                   "following patches, you may encounter big problems:\n\n"
                   "- new tooltypes\n"
                   "- reqtols patch\n"
                   "- onereq\n"
                   "- library search\n"
                   "- SetRGB32\n"
                   "\nYou may wish to ask the authors of MCP to fix this\n"
                   "- if not already done. So, be warned !"))
    (set #ppc (cat "\nWhen using SuperView-Libraries' PPC-Modules, make\n"
                   "sure, that you don't have powerpc.library V14+\n"
                   "installed together with ppc.library V45+.\n\n"
                   "Powerpc.library V7 should work, though."))

    (set #Msg_Yes "Yes")
    (set #Msg_No  "No")
    (set #Msg_BasicConfig "What's your basic configuration ?")
    (set #Gfx0  "Not specified (do not change)")
    (set #Gfx1  "Amiga OCS/ECS, no GfxCard")
    (set #Gfx2  "Amiga AGA, no GfxCard")
    (set #Gfx3  "CD-32 AGA, no GfxCard")
    (set #Gfx4  "Card with CyberGraphX emulation")
    (set #Gfx5  "Card with Picasso96 emulation")
    (set #Gfx6  "Card with EGS emulation")
    (set #Gfx7  "Picasso II(+)/IV")
    (set #Gfx8  "Retina Z2/BLT Z3")
    (set #Gfx9  "Merlin II")
    (set #Gfx10 "OpalVision")
    (set #Gfx11 "Amiga OCS/ECS/AGA, other GfxCard")
    (set #Msg_CopyEnvConfig "Copying appropriate configuration to ENV:")
    (set #Msg_LibPath "Library Path")
    (set #Msg_InstallingLibs "Copying Libraries...")
    (set #Msg_Ghostscript (cat "\nDo you already have Ghostscript installed ?\n\n"
                               "(When answering with <Yes>, you have to supply\n"
                               " the program's path and name here.)\n"
                         )
    )
    (set #Msg_GSPath "Path and name of Ghostscript executable")
    (set #Msg_MetaView    (cat "\nDo you already have MetaView installed ?\n\n"
                               "(When answering with <Yes>, you have to supply\n"
                               " the program's path and name here.)\n"
                         )
    )
    (set #Msg_MVPath "Path and name of MetaView executable")
    (set #Msg_CatPath "Catalog Path")
    (set #Msg_InstallingCats "Copying catalog files...")
    (set #Msg_VMEM "Now modifying your S:User-Startup for VMem-Support...")
    (set #Msg_VMemPath "Virtual Memory Path")
    (set #Msg_CopyPrefs "Copy SVPrefs to SYS:Prefs ?")
    (set #Msg_PackerSupport "Install PackerSupport right now ?")
    (set #Msg_SQOperators "Install SQ-Operators right now ?")
    (set #Msg_Ready "SuperView-Library has been installed now.\nIf this was an Update, you should\nreboot your computer now.")


(if (= @language "deutsch")
  (
    (set @app-name "SuperView-Library")
    (set #welc "SuperView-Library Installation")
    (set #mcp (cat "Falls bei Ihnen MCP installiert ist und sie nicht\n"
                   "folgende Patches deaktivieren, könnten größere\n"
                   "Probleme autreten:\n\n"
                   "- new tooltypes\n"
                   "- reqtols patch\n"
                   "- onereq\n"
                   "- library search\n"
                   "- SetRGB32\n"
                   "\nBitten Sie doch die MCP-Autoren, das ggf. zu\n"
                   "beheben, falls nicht bereits geschehen...\n"))
    (set #ppc (cat "\nBei Verwendung der PPC-Module der SuperView-Library\n"
                   "bitte sicherstellen, dass die powerpc.library V14+\n"
                   "nicht zusammen mit der ppc.library V45+ installier ist.\n\n"
                   "Powerpc.library V7 sollte jedoch funktionieren."))

    (set #Msg_Yes "Ja")
    (set #Msg_No  "Nein")
    (set #Msg_BasicConfig "Was ist Ihre Grundkonfiguration ?")
    (set #Gfx0  "Keine Angabe (nichts ändern)")
    (set #Gfx1  "Amiga OCS/ECS, keine Grafikkarte")
    (set #Gfx2  "Amiga AGA, keine Grafikkarte")
    (set #Gfx3  "CD-32 AGA, keine Grafikkarte")
    (set #Gfx4  "Karte mit CyberGraphX-Emulation")
    (set #Gfx5  "Karte mit Picasso96-Emulation")
    (set #Gfx6  "Karte mit EGS-Emulation")
    (set #Gfx7  "Picasso II(+)/IV")
    (set #Gfx8  "Retina Z2/BLT Z3")
    (set #Gfx9  "Merlin II")
    (set #Gfx10 "OpalVision")
    (set #Gfx11 "Amiga OCS/ECS/AGA, andere Grafikkarte")
    (set #Msg_CopyEnvConfig "Kopiere notwendige Konfiguration nach ENV:")
    (set #Msg_LibPath "Library-Pfad")
    (set #Msg_InstallingLibs "Kopiere Libraries...")
    (set #Msg_Ghostscript (cat "\nHaben Sie bereits Ghostscript installiert ?\n\n"
                               "(Falls <Ja>, müssen Sie hier nun den\n"
                               " Programmpfad und -namen angeben.)\n"
                         )
    )
    (set #Msg_GSPath "Pfad und Name des Ghostscript-Programmes")
    (set #Msg_MetaView    (cat "\nHaben Sie bereits MetaView installiert ?\n\n"
                               "(Falls <Ja>, müssen Sie hier nun den\n"
                               " Programmpfad und -namen angeben.)\n"
                         )
    )
    (set #Msg_MVPath "Pfad und Name des MetaView-Programmes")
    (set #Msg_CatPath "Katalogpfad")
    (set #Msg_InstallingCats "Kopiere Katalogdateien...")
    (set #Msg_VMEM "Ändere jetzt S:User-Startup für VMem-Unterstützung...")
    (set #Msg_VMemPath "Pfad für virtuellen Speicher")
    (set #Msg_CopyPrefs "SVPrefs nach SYS:Prefs kopieren ?")
    (set #Msg_PackerSupport "Packer-Unterstützung jetzt gleich installieren ?")
    (set #Msg_SQOperators "SQ-Operators jetzt gleich installieren ?")
    (set #Msg_Ready "SuperView-Library wurde installiert.\nFalls dies ein Update war, sollten Sie ggf.\nIhren Rechner nun neu starten.")
  )
)

(if (= @language "italiano")
  (
    (set #Msg_Yes "Si")
    (set #Msg_No  "No")
    (set #Msg_BasicConfig "Qual è la tua configurazione base ?")
    (set #Gfx0  "Non specificata (da non cambiare)")
    (set #Gfx1  "Amiga OCS/ECS, senza SchedaGfx")
    (set #Gfx2  "Amiga AGA, senza SchedaGfx")
    (set #Gfx3  "CD-32 AGA, senza SchedaGfx")
    (set #Gfx4  "Scheda con Emulazione-CyberGraphX")
    (set #Gfx5  "Scheda con Emulazione-Picasso96")
    (set #Gfx6  "Scheda con Emulazione-EGS")
    (set #Gfx7  "Picasso II(+)/IV")
    (set #Gfx8  "Retina Z2/BLT Z3")
    (set #Gfx9  "Merlin II")
    (set #Gfx10 "OpalVision")
    (set #Gfx11 "Amiga OCS/ECS/AGA, altra SchedaGfx")
    (set #Msg_CopyEnvConfig "Sto copiando configurazione appropriata in ENV:")
    (set #Msg_LibPath "Percorso Libreria")
    (set #Msg_InstallingLibs "Sto copiando Librerie...")
    (set #Msg_Ghostscript (cat "\nHai già installato il Ghostscript ?\n\n"
                               "(Se rispondi con <Si>, dovrai fornire\n"
                               "nome e percorso del programma qui.)\n"
                         )
    )
    (set #Msg_GSPath "Percorso e nome dell'eseguibile Ghostscript")
    (set #Msg_MetaView    (cat "\nHai già installato il MetaView ?\n\n"
                               "(Se rispondi con <Si>, dovrai fornire\n"
                               "nome e percorso del programma qui.)\n"
                         )
    )
    (set #Msg_MVPath "Percorso e nome dell'eseguibile MetaView")
    (set #Msg_CatPath "Percorso Catalogo")
    (set #Msg_InstallingCats "Sto copiando files del catalogo...")
    (set #Msg_VMEM "Ora modifico la tua S:User-Startup per supporto-VMem...")
    (set #Msg_VMemPath "Percorso Memoria Virtuale")
    (set #Msg_CopyPrefs "Copio SVPrefs in SYS:Prefs ?")
    (set #Msg_PackerSupport "Installo Supporto-Packer adesso ?")
    (set #Msg_SQOperators "Installo Operatori-SQ adesso ?")
    (set #Msg_Ready "Libreria-SuperView è stata ora installata.\nSe questo fosse un Aggiornamento, dovresti\neseguire un reboot del tuo computer ora.")
  )
)

(if (= @language "norsk")
  (
    (set #Msg_Yes "Ja")
    (set #Msg_No  "Nei")
    (set #Msg_BasicConfig "Hva er din standard konfigurasjon ?")
    (set #Gfx0  "Ikke spesifisert (ikke forandre)")
    (set #Gfx1  "Amiga OCS/ECS, ingen GfxKort")
    (set #Gfx2  "Amiga AGA, ingen GfxKort")
    (set #Gfx3  "CD-32 AGA, ingen GfxKort")
    (set #Gfx4  "Kort med CyberGraphX emulasjon")
    (set #Gfx5  "Kort med Picasso96 emulasjon")
    (set #Gfx6  "Kort med EGS emulasjon")
    (set #Gfx7  "Picasso II(+)/IV")
    (set #Gfx8  "Retina Z2/BLT Z3")
    (set #Gfx9  "Merlin II")
    (set #Gfx10 "OpalVision")
    (set #Gfx11 "Amiga OCS/ECS/AGA, annet GfxKort")
    (set #Msg_CopyEnvConfig "Kopierer passende konfigurasjon til ENV:")
    (set #Msg_LibPath "Bibliotek Sti (Library)")
    (set #Msg_InstallingLibs "Kopierer Bibliotek...")
    (set #Msg_Ghostscript (cat "\nHar du allerede Ghostscript installert ?\n\n"
                               "(Når du svarer med <Ja>, må du gi stien til\n"
                               " programmet og programmets navn her.)\n"
                         )
    )
    (set #Msg_GSPath "Sti og navn til Ghostscript program")
    (set #Msg_MetaView    (cat "\nHar du allerede MetaView installert ?\n\n"
                               "(Når du svarer med <Ja>, må du gi stien til\n"
                               " programmet og programmets navn her.)\n"
                         )
    )
    (set #Msg_MVPath "Stio og nanv til MetaView program")
    (set #Msg_CatPath "Katalog Sti")
    (set #Msg_InstallingCats "Kopierer katalog filer...")
    (set #Msg_VMEM "Modifiserer nå S:User-Startup for VMem-Støtte...")
    (set #Msg_VMemPath "Virtuellt Minne Sti")
    (set #Msg_CopyPrefs "Kopier SVPrefs til SYS:Prefs ?")
    (set #Msg_PackerSupport "Installer PackerStøtte nå?")
    (set #Msg_SQOperators "Installer SQ-Operatører (Operators) nå ?")
    (set #Msg_Ready "SuperView-Library er nå installert.\nHvis dette var en Oppdatering, bør du\nstarte maskinen på nytt.")
  )
)

(if (= @language "français")
  (
    (set #Msg_Yes "Oui")
    (set #Msg_No  "Non")
    (set #Msg_BasicConfig "Quelle est votre configuration de base ?")
    (set #Gfx0  "Non listée (ne rien changer)")
    (set #Gfx1  "Amiga OCS/ECS, pas de carte graphique")
    (set #Gfx2  "Amiga AGA, pas de carte graphique")
    (set #Gfx3  "CD-32 AGA, pas de carte graphique")
    (set #Gfx4  "Carte avec émulation CyberGraphX")
    (set #Gfx5  "Carte avec émulation Picasso96")
    (set #Gfx6  "Carte avec émulation EGS")
    (set #Gfx7  "Picasso II(+)/IV")
    (set #Gfx8  "Retina Z2/BLT Z3")
    (set #Gfx9  "Merlin II")
    (set #Gfx10 "OpalVision")
    (set #Gfx11 "Amiga OCS/ECS/AGA, autre carte graphique")
    (set #Msg_CopyEnvConfig "Copie de la configuration appropriée dans ENV:")
    (set #Msg_LibPath "Chemin des librairies")
    (set #Msg_InstallingLibs "Copie des librairies...")
    (set #Msg_Ghostscript (cat "\nAvez-vous déjà installé Ghostscript ?\n\n"
                               "(Si vous répondez par <Oui>, il vous faudra fournir\n"
                               " le chemin du programme et son nom.)\n"
                         )
    )
    (set #Msg_GSPath "Chemin et nom de l'exécutable Ghostscript")
    (set #Msg_MetaView    (cat "\nAvez-vous déjà installé MetaView ?\n\n"
                               "(Si vous répondez par <Oui>, il vous faudra fournir\n"
                               " le chemin du programme et son nom.)\n"
                         )
    )
    (set #Msg_MVPath "Chemin et nom de l'exécutable MetaView")
    (set #Msg_CatPath "Chemin des catalogues")
    (set #Msg_InstallingCats "Copie des fichiers catalogues...")
    (set #Msg_VMEM "Modification de votre S:User-Startup au niveau de VMem-Support...")
    (set #Msg_VMemPath "Chemin de la mémoire virtuelle")
    (set #Msg_CopyPrefs "Copier SVPrefs dans SYS:Prefs ?")
    (set #Msg_PackerSupport "Installer le PackerSupport maintenant ?")
    (set #Msg_SQOperators "Installer les SQ-Operators maintenant ?")
    (set #Msg_Ready "SuperView-Library a été installé avec succès.\nS'il s'agissait d'une mise à jour, vous devriez\nredémarrer votre ordinateur maintenant.")
  )
)

(if (= @language "español")
  (
    (set @app-name "Biblioteca SuperView")
    (set #welc "Instalación de la biblioteca SuperView")

    (set #mcp (cat "Si está ejecutando la comodidad MCP y no desconecta\n"
                   "los siguientes parches, podría encontrarse con\n"
                   "graves problemas:\n\n"
                   "- nuevos tipos de herramienta ('new tooltypes')\n"
                   "- parche reqtols ('reqtools patch')\n"
                   "- petición única ('onereq')\n"
                   "- búsqueda de bibliotecas ('library search')\n"
                   "- SetRGB32\n"
                   "\nLe aconsejo que, si los autores de MCP no los han\n"
                   "corregido aún, ¡tenga mucho cuidado! y les informe."))

     (set #ppc (cat "\nCuando utilice los módulos PPC para la biblioteca\n"
                    "'superview.library', asegúrese de que no se encuentra\n"
                    "instalada la biblioteca 'powerpc.library' versión 14+\n"
                    "junto con la biblioteca 'ppc.library' versión 45+.\n\n"
                    "Sin embargo, con la biblioteca 'powerpc.library'\n"
                    "versión 7 no deberían surgir problemas.")
                )

    (set #Msg_Yes "Sí")
    (set #Msg_No  "No")
    (set #Msg_BasicConfig "¿Cual es su configuración básica?")
    (set #Gfx0  "No especificada (no modificar)")
    (set #Gfx1  "Amiga OCS/ECS, sin tarjeta gráfica")
    (set #Gfx2  "Amiga AGA, sin tarjeta gráfica")
    (set #Gfx3  "CD-32 AGA, sin tarjeta gráfica")
    (set #Gfx4  "Tarjeta con emulación CyberGraphX")
    (set #Gfx5  "Tarjeta con emulación Picasso96")
    (set #Gfx6  "Tarjeta con emulación EGS")
    (set #Gfx7  "Picasso II(+)/IV")
    (set #Gfx8  "Retina Z2/BLT Z3")
    (set #Gfx9  "Merlin II")
    (set #Gfx10 "OpalVision")
    (set #Gfx11 "Amiga OCS/ECS/AGA, con otra tarjeta gráfica")
    (set #Msg_CopyEnvConfig "Copiando configuración apropiada en ENV:")
    (set #Msg_LibPath "Elija el camino de acceso a las bibliotecas")
    (set #Msg_InstallingLibs "Copiando bibliotecas...")
    (set #Msg_Ghostscript (cat "\n¿Se encuentra instalado Ghostscript en su sistema?\n\n"
                               "(si responde afirmativamente deberá suministrar\n"
                               "el camino de acceso y nombre del ejecutable).\n"
                         )
    )
    (set #Msg_GSPath "Camino de acceso y nombre del ejecutable Ghostscript")
    (set #Msg_MetaView    (cat "\n¿Se encuentra instalado MetaView en su sistema?\n\n"
                               "(si responde afirmativamente deberá suministrar\n"
                               "el camino de acceso y nombre del ejecutable).\n"
                         )
    )
    (set #Msg_MVPath "Camino de acceso y nombre del ejecutable MetaView")
    (set #Msg_CatPath "Elija el lugar donde desea instalar los catálogos")
    (set #Msg_InstallingCats "Copiando catálogos...")
    (set #Msg_VMEM "Modificando su fichero S:User-Startup para el soporte de memoria virtual...")
    (set #Msg_VMemPath "Camino de acceso a la memoria virtual")
    (set #Msg_CopyPrefs "¿Desea copiar SVPrefs a SYS:Prefs ?")
    (set #Msg_PackerSupport "¿Desea instalar ahora el módulo de empaquetado/compresión?")
    (set #Msg_SQOperators "¿Desea instalar ahora los operadores SQ?")
    (set #Msg_Ready "La biblioteca SuperView ha sido instalada.\nSi se trata de una actualización,\ndebería reiniciar su equipo inmediatamente.")
  )
)

(welcome #welc)
(message #mcp)

(set #cpu (database "cpu")) (if (> (exists ("sys:libs/68060.library")) 0)   (set #cpu     "68060")  )
(set #ppc_cpu "none")       (if (> (exists ("sys:libs/ppc.library")) 0)     (set #ppc_cpu "PPC60x") )
                            (if (> (exists ("sys:libs/PowerPC.library")) 0) (set #ppc_cpu "PPC60x") )

(if (= #ppc_cpu "PPC60x")
 (
  (message #ppc)
 )
)

; **************************************************************************
; Create/Update basic configuration

(makedir "ENV:SuperView-Library" (safe))
(makedir "ENVARC:SuperView-Library" (safe))

(set #selectsvdriver (askchoice
                      (prompt #Msg_BasicConfig)
                      (help @askchoice-help)
                      (choices #Gfx0 #Gfx1 #Gfx2 #Gfx3 #Gfx4 #Gfx5 #Gfx6 #Gfx7 #Gfx8 #Gfx9 #Gfx10 #Gfx11)
                      (default 1)
                    )
)

(if (= #selectsvdriver 1)  (set #env_source "docs/SampleConfigs/env_ECS")           )
(if (= #selectsvdriver 2)  (set #env_source "docs/SampleConfigs/env_AGA")           )
(if (= #selectsvdriver 3)  (set #env_source "docs/SampleConfigs/env_AGA_CD32")      )
(if (= #selectsvdriver 4)  (set #env_source "docs/SampleConfigs/env_CyberGraphics") )
(if (= #selectsvdriver 5)  (set #env_source "docs/SampleConfigs/env_Picasso96")     )
(if (= #selectsvdriver 6)  (set #env_source "docs/SampleConfigs/env_EGS7")          )
(if (= #selectsvdriver 7)  (set #env_source "docs/SampleConfigs/env_PicassoII")     )
(if (= #selectsvdriver 8)  (set #env_source "docs/SampleConfigs/env_Retina")        )
(if (= #selectsvdriver 9)  (set #env_source "docs/SampleConfigs/env_Merlin")        )
(if (= #selectsvdriver 10) (set #env_source "docs/SampleConfigs/env_OpalVision")    )
(if (= #selectsvdriver 11) (set #env_source "docs/SampleConfigs/env_GfxCards")      )

(if (> #selectsvdriver 0)
  (
    (copyfiles
      (prompt #Msg_CopyEnvConfig)
      (help @copyfiles-help)
      (source #env_source)
      (dest "ENV:")
      (all)
    )
    (copyfiles
      (prompt #Msg_CopyEnvConfig)
      (help @copyfiles-help)
      (source #env_source)
      (dest "ENVARC:")
      (all)
    )
  )
)

(copyfiles
  (prompt #Msg_CopyEnvConfig)
  (help @copyfiles-help)
  (source "env")
  (dest "ENVARC:")
  (all)
)

; **************************************************************************
; Install main libraries

(if (exists "ENVARC:SuperView-Library/SVLIB_WHERE") (set #svlibdir (getenv "SuperView-Library/SVLIB_WHERE"))

 (set #svlibdir "LIBS:")
)

(if (= (exists (#svlibdir)) 0) (set #svlibdir "LIBS:") )

(set #svlibdir
              (askdir
                      (prompt #Msg_LibPath)
                      (help @askdir-help)
                      (newpath)
                      (default #svlibdir)
               )
)

(delete "ENVARC:SuperView-Library/SVLIB_WHERE")
(delete "ENV:SuperView-Library/SVLIB_WHERE")
(textfile (dest "ENVARC:SuperView-Library/SVLIB_WHERE") (append #svlibdir) (safe))
(textfile (dest "ENV:SuperView-Library/SVLIB_WHERE") (append #svlibdir) (safe))

(copylib
  (prompt #Msg_InstallingLibs)
  (help @copylib-help)
  (source "libs/superview.library")
  (dest #svlibdir)
)

(set @default-dest #svlibdir)

(copylib
  (prompt #Msg_InstallingLibs)
  (help @copylib-help)
  (source "libs/superviewsupport.library")
  (dest #svlibdir)
)

; **************************************************************************
; Ask for Ghostscript

(if (exists "libs/svobjects/Ghostscript.svobject")
  (
    (set #gsquest (askchoice
                    (prompt #Msg_Ghostscript)
                    (help @askchoice-help)
                    (choices #Msg_Yes #Msg_No)
                    (default 1)
                  )
    )

    (if (= #gsquest 0)
      (
        (set #gspath (askfile
                      (prompt #Msg_GSPath)
                      (help @askfile-help)
                      (default "gs000")
                    )
        )
        (set #gspathopt (cat "GS_PATH=" #gspath "\n"))
        (textfile
          (dest "ENV:SuperView-Library/Ghostscript.controlpad")
          (append #gspathopt)
        )
        (copyfiles
          (source "ENV:SuperView-Library/Ghostscript.controlpad")
          (dest "ENVARC:SuperView-Library")
        )
      )
    )
) )

; **************************************************************************
; Ask for MetaView

(if (exists "libs/svobjects/MetaView.svobject")
  (
    (set #mvquest (askchoice
                    (prompt #Msg_MetaView)
                    (help @askchoice-help)
                    (choices #Msg_Yes #Msg_No)
                    (default 1)
                  )
    )

    (if (= #mvquest 0)
      (
        (set #mvpath (askfile
                      (prompt #Msg_MVPath)
                      (help @askfile-help)
                      (default "MetaView")
                    )
        )
        (set #mvpathopt (cat "METAVIEW_PATH=" #mvpath "\n"))
        (textfile
          (dest "ENV:SuperView-Library/MetaView.controlpad")
          (append #mvpathopt)
        )
        (copyfiles
          (source "ENV:SuperView-Library/MetaView.controlpad")
          (dest "ENVARC:SuperView-Library")
        )
      )
    )
  )
)

; **************************************************************************
; Install catalogs

(makedir "SYS:locale")
(makedir "SYS:locale/catalogs")

(copyfiles
  (prompt #Msg_InstallingCats)
  (help @copyfiles-help)
  (source "locale/catalogs")
  (set #svcatdir
              (askdir
                     (prompt #Msg_CatPath)
                     (help @askdir-help)
                     (newpath)
                     (default "SYS:locale/Catalogs")
              )
  )
  (dest #svcatdir)
  (all)
)

; **************************************************************************
; Install library modules

(set #svobjectdir   (tackon #svlibdir "svobjects"))
(set #svdriverdir   (tackon #svlibdir "svdrivers"))
(set #svoperatordir (tackon #svlibdir "svoperators"))
(set #svstoredir    (tackon #svlibdir "svstorage"))

(makedir #svobjectdir)
(makedir #svdriverdir)
(makedir #svoperatordir)
(makedir #svstoredir)

(copyfiles
  (prompt #Msg_InstallingLibs)
  (help @copyfiles-help)
  (source "libs/svobjects")
  (dest (tackon #svlibdir "svobjects"))
  (pattern "#?")
  (confirm)
  (files)
)

(if (exists(tackon #svobjectdir "SVO.svobject"))
 (rename (tackon #svobjectdir "SVO.svobject") (tackon #svstoredir "SVO.svobject") (safe))
)

(if (exists(tackon #svobjectdir "CyberDataType.svobject"))
 (rename (tackon #svobjectdir "CyberDataType.svobject") (tackon #svstoredir "CyberDataType.svobject") (safe))
)

(copyfiles
  (prompt #Msg_InstallingLibs)
  (help @copyfiles-help)
  (source "libs/svdrivers")
  (dest (tackon #svlibdir "svdrivers"))
  (pattern "#?")
  (confirm)
  (files)
)

(if (NOT (= #selectsvdriver 5))
 (rename (tackon #svdriverdir "Picasso96.svdriver") (tackon #svstoredir "Picasso96.svdriver") (safe))
)

(if (NOT (= #selectsvdriver 6))
 (rename (tackon #svdriverdir "EGS7.svdriver") (tackon #svstoredir "EGS7.svdriver") (safe))
)

(if (NOT (= #selectsvdriver 7))
 (rename (tackon #svdriverdir "PicassoII.svdriver") (tackon #svstoredir "PicassoII.svdriver") (safe))
)

(if (NOT (= #selectsvdriver 8))
 (rename (tackon #svdriverdir "Retina.svdriver") (tackon #svstoredir "Retina.svdriver") (safe))
)

(if (NOT (= #selectsvdriver 9))
 (rename (tackon #svdriverdir "MERLIN.svdriver") (tackon #svstoredir "MERLIN.svdriver") (safe))
)

(if (NOT (= #selectsvdriver 10))
 (rename (tackon #svdriverdir "OPAL.svdriver") (tackon #svstoredir "OPAL.svdriver") (safe))
)

(copyfiles
  (prompt #Msg_InstallingLibs)
  (help @copyfiles-help)
  (source "libs/svoperators")
  (dest (tackon #svlibdir "svoperators"))
  (pattern "#?")
  (confirm)
  (files)
)

(if (exists "libs/68030")
  (
    (if (>= #cpu 68020)
      (
        (copyfiles
          (prompt #Msg_InstallingLibs)
          (help @copyfiles-help)
          (source "libs/68030")
          (dest #svlibdir)
          (confirm)
          (all)
        )
      )
    )
  )
)

; **************************************************************************
; Modify User-Startup

(if (exists "ENVARC:SuperView-Library/SVMEM_WHERE") (set #vmemdir (getenv "SuperView-Library/SVMEM_WHERE"))

 (set #vmemdir "T:")
)

(if (= (exists (#vmemdir)) 0) (set #vmemdir "T:") )

(set #vmemdir
              (askdir
                (prompt #Msg_VMemPath)
                (help @askdir-help)
                (newpath)
                (default #vmemdir)
              )
)

(delete "ENVARC:SuperView-Library/SVMEM_WHERE")
(delete "ENV:SuperView-Library/SVMEM_WHERE")
(textfile (dest "ENVARC:SuperView-Library/SVMEM_WHERE") (append #vmemdir) (safe))
(textfile (dest "ENV:SuperView-Library/SVMEM_WHERE") (append #vmemdir) (safe))

(startup "SuperView-Library"
  (prompt #Msg_VMEM)
  (help @startup-help)
  (command "Assign VMEM: "#vmemdir"\nSVPrefs >NIL: <NIL: INIT\n")
)

; **************************************************************************
; Install SVPrefs

(copyfiles
  (prompt #Msg_CopyPrefs)
  (help @copyfiles-help)
  (source "Prefs")
  (dest "SYS:Prefs")
  (all)
  (confirm)
)

; **************************************************************************
; Ask for Packersupport

(if (exists "PackerSupport")
  (
    (set #ask_ps (askbool (prompt #Msg_PackerSupport) (help @askbool-help) ) )

    (if (= #ask_ps TRUE)
      (
        (copyfiles
          (prompt #Msg_InstallingLibs)
          (help @copyfiles-help)
          (source "PackerSupport/libs/svobjects")
          (dest (tackon #svlibdir "svobjects"))
          (pattern "#?")
          (files)
        )
      )
    )
  )
)

; **************************************************************************
; Ask for SQOperators

(if (exists "SQ-Operators")
  (
    (set #ask_sq (askbool (prompt #Msg_SQOperators) (help @askbool-help) ) )

    (if (= #ask_sq TRUE)
      (
        (copyfiles
          (prompt #Msg_CopyEnvConfig)
          (help @copyfiles-help)
          (source "SQ-Operators/envarc")
          (dest "ENVARC:")
          (all)
        )
        (copyfiles
          (prompt #Msg_InstallingLibs)
          (help @copyfiles-help)
          (source "SQ-Operators/libs/svoperators")
          (dest (tackon #svlibdir "svoperators"))
          (pattern "#?")
          (confirm)
          (files)
        )
      )
    )
  )
)

; **************************************************************************
; EOF ;-)

(exit #Msg_Ready)