/*****************************************************************
**                                                              **
**      ShowTln.ecfg                    EuraConfig-Script       **
**      Zeigt Informationen über einen Teilnehmer               **
**                                                              **
******************************************************************
**
**      V1.1 -- (C) 1997 Richard Körber -- All Rights Reserved
**
**/

OPTIONS RESULTS
OPTIONS FAILAT 20
IF Left(Address(),10)~='EURACONFIG' THEN ADDRESS 'EURACONFIG.1'

/*---- SCRIPT STARTS HERE --------------------------------------*/

'VERSION CHECK=3'               /* Richtige Kommando-Version? */

flags.0 = "Nein"                /* BOOL -> Text */
flags.1 = "Ja"

typ.0   = "Telefon"             /* Gerätetyp */
typ.1   = "Anrufbeantworter"
typ.2   = "Fax"
typ.3   = "Modem"
typ.4   = "Multifunktional"
typ.5   = "Türsprechanlage"
typ.6   = "ISDN"

amt.0   = "Keine"               /* Amtsberechtigungen */
amt.1   = "Kommend"
amt.2   = "Ortsgespräch"
amt.3   = "Nahbereich"
amt.4   = "Inland"
amt.5   = "Unbegrenzt"

desc.0  = "Masterberechtigung"  /* Flag -> Text */
desc.1  = "Aufschaltschutz"
desc.2  = "Aufschalt"
desc.3  = "Rufverteilung Tag, Anlage A"
desc.4  = "Rufverteilung Tag, Anlage B"
desc.5  = "Rufverteilung Nacht, Anlage A"
desc.6  = "Rufverteilung Nacht, Anlage B"
desc.7  = "Türruf 1, Anlage A"
desc.8  = "Türruf 1, Anlage B"
desc.9  = "Türruf 2, Anlage A"
desc.10 = "Türruf 2, Anlage B"
desc.11 = "Rufweiterschaltung, Anlage A"
desc.12 = "Rufweiterschaltung, Anlage B"
desc.13 = "Zweitwecker 1"
desc.14 = "Zweitwecker 2"
desc.15 = "Gebührendruck"
desc.16 = "Komplette Rufnummer drucken"
desc.17 = "Gekürzte Rufnummer drucken"
desc.18 = "Gebührenimpuls"
desc.19 = "Anklopfschutz"
desc.20 = "Aufschaltschutz"
desc.21 = "Ruhe vor dem Telefon"
desc.22 = "Hotline"
desc.23 = "Raumüberwachung"
desc.24 = "CLIR"
desc.25 = "COLR"
desc.26 = "Weckzeit"


/*--- Die Auswertung beginnt hier ---*/
SAY "Welcher Teilnehmer?"       /* Teilnehmer-Nr. erfragen */
PARSE PULL tln

DO ix = 0 TO 9                  /* Alle Daten auslesen und in einen Stem eintragen */
  'TLN "'||tln||'" "'||ix||'"'
  IF RC~=0 THEN DO
    SAY "Teilnehmer existiert nicht"
    EXIT
  END
  tl.ix = result
END

SAY ""                          /* Leerzeile */

                                /* Infos über den Teilnehmer ausgeben */
SAY "Teilnehmer Nr." tl.1 "("||tl.0||")"
SAY Left("",40,"-")
SAY Left("Gebührensumme",30)||":" tl.3%100||","||Right(tl.3//100,2,"0") "DM"
SAY Left("Gebührenfaktor",30)||":" tl.2 "Pfg"
hilf = tl.5
SAY Left("Gerätetyp",30)||":" typ.hilf
hilf = tl.4
SAY Left("Amtsberechtigung",30)||":" amt.hilf

SAY ""
DO flag = 0 TO 26
  'TLNFLAGS "'||tln||'" "'||flag||'"'
  SAY Left(desc.flag,30)||":" flags.result
END

SAY ""
SAY Left("Weckzeit",30)||":" Right(tl.6%60,2)||":"||Right(tl.6//60,2,"0")
SAY Left("Rufumleitungs-Zeit",30)||":" tl.7 "sec."
SAY Left("Rufumleitung bei Besetzt",30)||":" tl.8
SAY Left("Rufumleitung nach Zeit",30)||":" tl.8

SAY ""
SAY "Zugewiesene Rufnummern:"
DO port = 1 TO 3
  DO msn = 0 TO 9
    'TLNMSN "'||tln||'" "'||port||'" "'||msn||'"'
    IF result = '1' THEN DO
      'PORT "'||port||'" "'||msn+2||'"'
      SAY "  Port" port "MSN" msn "= Rufnr." result
    END
  END
END

SAY ""
SAY ""
/*---- SCRIPT ENDS HERE ----------------------------------------*/

EXIT