/*****************************************************************
**                                                              **
**      ShowAlarm.ecfg                  EuraConfig-Script       **
**      Zeigt die Alarm-Einstellungen                           **
**                                                              **
******************************************************************
**
**      V1.0 -- (C) 1997 Richard Körber -- All Rights Reserved
**
**/

OPTIONS RESULTS
OPTIONS FAILAT 6
IF Left(Address(),10)~='EURACONFIG' THEN ADDRESS 'EURACONFIG.1'

/*---- SCRIPT STARTS HERE --------------------------------------*/

'VERSION CHECK=2'               /* Richtige Kommando-Version? */

 /*-- Stem-Variablen initialisieren --*/
modus.0 = "schließen"           /* Schalt-Modus festlegen */
modus.1 = "öffnen"
modus.2 = "deaktiviert"

 /*-- Sensor-Zeiten anzeigen --*/
'ALARM FIELD=0'; startzeit = result     /* In Minuten seit 0:00 */
'ALARM FIELD=1'; endzeit   = result
SAY "Startzeit: "||Right(startzeit%60,2)||":"||Right(startzeit//60,2,'0')
SAY "Endzeit:   "||Right(endzeit%60,2)||":"||Right(endzeit//60,2,'0')
SAY ""

 /*-- Aktor 1 anzeigen --*/
'ALARM FIELD=2'; zeit = result; IF zeit=0 THEN zeit="dauernd"; ELSE zeit=zeit||"s"
'ALARM FIELD=3'; mode = result
SAY "Aktor 1:   Schaltzeit "||zeit||", Modus "||modus.mode

 /*-- Aktor 2 anzeigen --*/
'ALARM FIELD=4'; zeit = result; IF zeit=0 THEN zeit="dauernd"; ELSE zeit=zeit||"s"
'ALARM FIELD=5'; mode = result
SAY "Aktor 2:   Schaltzeit "||zeit||", Modus "||modus.mode
SAY ""

 /*-- Automatische Anwahl --*/
'ALARM FIELD=6'; aa = result
IF aa~="0" THEN DO
  SAY "Automatische Anwahl aktiviert."

  DO i=0 TO 2
    'ALARM FIELD='||i+7
    SAY "  Rufnummer "||i+1||": "||result
  END

  'ALARM FIELD=10'
  SAY "  User2User-Nachricht: '"||result||"'"
END
ELSE
  SAY "Keine automatische Anwahl aktiviert."

SAY ""
SAY ""
/*---- SCRIPT ENDS HERE ----------------------------------------*/

EXIT