; $VER: Worm Wars 5.61 (26.4.2000)
; Installer script for Worm Wars
; © Copyright 2000 Amigan Software
; Required: Installer 42.9+. Recommended: Installer 44+.

(set @app-name ("Worm Wars 5.6"))
(welcome "Welcome to the Worm Wars 5.6 installation/uninstallation script!")
(if (>= @installer-version 44)
    (effect "center" "radial" $FFFF00 $0000FF)
)

(complete 0)

(set #mainchoice
    (askchoice
        (prompt "Would you like to:")
        (choices
            "Install Worm Wars"
            "Uninstall Worm Wars"
        )
        (default 0)
        (help "It is not necessary to uninstall a previous version of Worm Wars before installing Worm Wars 5.6.")
    )
)
(complete 5)

(if (= #mainchoice 0)
(   (set #new_dir
        (askdir
            (prompt "Where do you want to install Worm Wars?\n"
            "A drawer called \"WormWars\" will be created.\n")
            (default "SYS:")
            (help "This is self-explanatory.")
        )
    )
    (set @default-dest (tackon #new_dir "WormWars"))
    (makedir @default-dest (infos))
    (complete 10)
    (copylib
        (prompt "Installing MEDPlayer.library to LIBS:")
        (help "Worm Wars can use MEDPlayer.library to play music.")
        (source "medplayer.library")
        (dest "LIBS:")
        (confirm)
    )
    (complete 30)

    (set #fontchoice
	(askchoice
		(prompt "Would you like to install WormWars.font?")
		(help "Worm Wars can use this 8x8 monospaced font rather than Topaz 8.")
		(choices "Yes" "No")
		(default 0)
	)
    )
    (if (= #fontchoice 0)
    (	(copyfiles
	    (source "WormWars.font")
	    (dest "FONTS:")
        )
        (complete 35)
        (makedir ("FONTS:WormWars"))
        (complete 40)
        (copyfiles
        (source "WormWars/8")
        (dest "FONTS:WormWars")
    ))
    (complete 50)
    (copyfiles
        (prompt "Copying other files...")
	(source "")
	(help @copyfiles-help)
	(dest @default-dest)
	(all)
	(infos)
    )
    (complete 75)
    (delete (tackon @default-dest "MEDPlayer.library"))
    (complete 80)
    (delete (tackon @default-dest "WormWars.font"))
    (complete 85)
    (delete (tackon @default-dest "WormWars/8"))
    (complete 90)
    (delete (tackon @default-dest "WormWars"))
)))

;Possible installation enhancements:
; copy directory .info file, instead of making a new one
; delete original directory and all subdirectories of it
; options as to whether to install the effects and/or source code

(if (= #mainchoice 1)
(
    (set #the_dir
        (askdir
            (prompt "In which drawer is the Worm Wars executable located?")
            (default "PROGDIR:")
            (help "This is self-explanatory.")
    )   )
    (set @default-dest (#the_dir))
    (delete
        (@default-dest)
        (all)
        (optional force)
    )
    (complete 65)
    (delete
        ("/WormWars#?")
        (optional force)
    )
    (complete 70)
    (delete
        ("LIBS:MEDPlayer.library")
        (confirm)
        (prompt "About to delete LIBS:MEDPlayer.library...")
        (help "This is self-explanatory.")
    )
    (complete 80)
    (set #fontchoice
        (askchoice
            (prompt "Do you want to delete the Worm Wars font?")
            (help "This font is useful as a general-purpose font.")
            (choices "Yes" "No")
            (default 1)
    )   )
    (complete 90)
    (if (= #fontchoice 0)
    (   (delete ("FONTS:WormWars.font"))
        (delete ("FONTS:WormWars/8"))
        (delete ("FONTS:WormWars"))
    ))
))

(complete 100)
(exit bye)