; ****************************************
; *** $VER: Install_EO V1.10 (18.3.96) ***
; *** Copyright ©1996 by Mathew Wilson ***
; ****************************************

; * Script Version 1.10 *
; - Now copies the Introduction.guide to the Installation drawer.
; - Changes tooltypes on Alarmist, Locate, On-Time and Tasker in
;   reference to ARexx scripts.

; * Script Version 1.00 *
; Original Release.

; ----------------------------------------

(complete 0)

; *** Introduction ***

; get source root dir
(set path (pathonly @icon))

(welcome)

(message "\n"
	"Everyday Organiser v1.10 ©1996 by Mathew Wilson\n\n"
	"All the programs in this archive are\n"
	"classified as FreeWare.\n\n"
	"You *must* have at least MUI version 3.3 installed\n"
	"to operate most of these programs!\n"
	"---------------------------------------------------"
)

; ** Installation Preparation ***

(welcome)

(set destination
   (askdir
      (prompt "Where would you like the applications to be installed?\n(A new directory called EverydayOrganiser will be created there.)\nUpdates will OVERWRITE the old programs!")
      (help   "This is where the EO programs will be copied to.\n\n"@askdir-help)
      (default "SYS:Utilities")
   )
)

(set root-dest destination)
(set @default-dest destination)

(set destination (tackon destination "EverydayOrganiser"))

(set @default-dest destination)

(copylib
   (source "libs/everyday.library")
   (dest "LIBS:")
)

(complete 10)

(copyfiles
   (help @copyfiles-help)
   (source "EverydayOrganiser/")
   (dest destination)
   (all)
   (infos)
)

(complete 20)

(copyfiles
   (source "EverydayOrganiser.info")
   (dest root-dest)
)

(complete 30)

; ** Modify Main Program tooltypes so that some ARexx scripts can be found **

(tooltype
	(dest (tackon destination "Locate"))
	(settooltype "DROP_SCRIPT" (tackon destination "rexx/Locate_DropObj.rexx"))
)

(tooltype
	(dest (tackon destination "OnTime"))
	(settooltype "DROP_SCRIPT" (tackon destination "rexx/OnTime_DropObj.rexx"))
)

(tooltype
	(dest (tackon destination "Alarmist"))
	(settooltype "DROP_SCRIPT" (tackon destination "rexx/Alarmist_DropObj.rexx"))
)

(tooltype
	(dest (tackon destination "Alarmist"))
	(settooltype "CHIME_EXEC" (tackon destination "rexx/Alarmist_Chime.rexx"))
)

(tooltype
	(dest (tackon destination "Alarmist"))
	(settooltype "WARN_EXEC" (tackon destination "rexx/Alarmist_Warn.rexx"))
)

(tooltype
	(dest (tackon destination "Tasker"))
	(settooltype "DROP_SCRIPT" (tackon destination "rexx/Tasker_DropObj.rexx"))
)

(complete 40)

; ** Copy Alarmist into WBStartup ? **

(if
   (> @user-level 1)
   
   (set choice (askbool
      (help @askbool-help)
      (prompt "Would you like Alarmist copied to your "
			"SYS:WBStartup drawer?\n\nThis is recommended!")
      (default 1))
   )
   
   (set choice 1)
)

(if
	(= choice 1)
	
	(copyfiles
      (source destination)
      (dest "SYS:WBStartup/")
      (choices "Alarmist" "Alarmist.info" "Alarmist_World.data")
      (files)
   )
)

; ** Copy the AmigaGuides to the Locale:help/english drawer **

(if
   (> @user-level 1)

   (set choice (askbool
      (help @askbool-help)
      (prompt "Would you like the AmigaGuides for the main programs "
              "copied to Locale:help?\n\nThis is recommended!")
      (default 1))
   )
   
   (set choice 1)
)

(if
   (= choice 1)

   (copyfiles
      (source "EverydayOrganiser/")
      (dest "Locale:help/english")
      (pattern "#?.guide")
      (files)
   )
)

(complete 50)

; ** Copy some of the extra programs to different places **

(set choice
   (askoptions
      (prompt "The extra programs are in the Extras drawer\n"
              "but they should be copied to their normal drawers\n\n"
              "Please choose which of the following to copy.")
      (choices "TimePrefs (destination SYS:Prefs)" "Talk      (destination C:)" "Sam       (destination C:)" "Coder     (destination C:)")
      (help @askoptions-help)
   )
)

; ** copy TimePrefs **
(if
   (<> 0 (BITAND choice 1))
   (
      (copyfiles
         (source "EverydayOrganiser/Extras/TimePrefs")
         (dest "sys:prefs")
         (infos)
      )
      
      (delete (tackon destination "Extras/TimePrefs"))
      (delete (tackon destination "Extras/TimePrefs.info"))
   )
)

(complete 60)

; ** copy Talk? **
(if
   (<> 0 (BITAND choice 2))
   (
      (copyfiles
         (source "EverydayOrganiser/Extras/Talk")
         (dest "C:")
      )
   )
)

(complete 75)

; ** Copy Talk defaults file to s: **
(copyfiles
	(source "EverydayOrganiser/Extras/Talk_Defaults")
	(dest "s:")
)



; ** copy Sam? **
(if
   (<> 0 (BITAND choice 4))
   (
      (copyfiles
         (source "EverydayOrganiser/Extras/Sam")
         (dest "C:")
      )
   )
)

(complete 80)

; ** copy Coder? **
(if
   (<> 0 (BITAND choice 8))
   (
      (copyfiles
         (source "EverydayOrganiser/Extras/Coder")
         (dest "C:")
      )
   )
)

(complete 90)

; ** Copy the Introduction.Guide to the installation drawer **
(set intro_doc (tackon path "Introduction.guide"))

(copyfiles
	(source intro_doc)
	(dest destination)
	(infos)
)

(set intro_doc (tackon destination "Introduction.guide"))

(tooltype
	(dest intro_doc)
	(noposition)
)

(complete 100)

(transcript "\nEveryday Organiser installed to "destination"\n")

; ** Let's annoy the user with the Intro doc :) **
(run "sys:utilities/multiview" ("\"%s\"" intro_doc) (safe))

(debug file)

(exit "I hope you find Everyday Organiser useful.\n")