/*
	$VER: Tape.filer 1.2 (26.11.93)

	Author:
		Robert Rethemeyer				(rr)
			tape.rexx from BTN distrib
		Michael Böhnisch (billy@uni-paderborn.de)	(mb)
			Modified to interface Filer,
			general cleanup

	Function:
		Sends useful commands to tape drive via BTN handler.

	Call:
		Tape REWIND	Rewind medium
		Tape RETENSION	Retension medium
		Tape END	Position to end of recorded medium
		Tape BACKWARD	Position on start of previous file
		Tape FORWARD	Position on start of next file
		Tape WFM	Write file mark to tape
		Tape ERASE	Erase medium

	Example for Filer.RC:
		XBUTTON 2,3,1,1,"End","Tape END"
		XBUTTON 2,0,1,1,"Rewind","Tape REWIND"
		XBUTTON 2,0,2,1,"Retension","Tape RETENSION"
		XBUTTON 2,1,1,1,"Back","Tape BACKWARD"
		XBUTTON 2,1,2,1,"Write FM","Tape WFM"
		XBUTTON 2,2,1,1,"Fwd","Tape FORWARD"
		XBUTTON 2,2,2,4,"Erase","Tape ERASE"

	History:
		22.10.91	(1.0) Initial Release (BTN packet, rr)
		23.09.93	1.1 Changed to accomodate Filer (mb)
		26.11.93	1.2 Review for Filer 3.10 Gamma 2
*/

OPTIONS RESULTS

ADDRESS 'FilerRexx'

PANEL OFF

PARSE ARG cmd .

drive = "TAPE"

SELECT
  WHEN abbrev( "REWIND"   , cmd, 3 ) THEN edata = "01"
  WHEN abbrev( "RETENSION", cmd, 3 ) THEN edata = "1B 00 00 00 03 00"
  WHEN abbrev( "END"      , cmd, 3 ) THEN edata = "11 03"
  WHEN abbrev( "WFM"      , cmd, 3 ) THEN edata = "10 00 00 00 01"
  WHEN abbrev( "FORWARD"  , cmd, 1 ) THEN edata = "11 01 00 00 01"
  WHEN abbrev( "BACKWARD" , cmd, 1 ) THEN DO
    SHELL COMMAND 'echo >'drive':RAWCMD "11 01 FF FF FE"' /* 2 steps back   */
    edata = "11 01 00 00 01"				  /* 1 step forward */
  END
  WHEN abbrev( "ERASE"    , cmd, 3 ) THEN DO
    QUESTBOX "REALLY erase Tape?"
    IF RESULT = 'RESULT' THEN EXIT 5
    IF RESULT = 0 THEN SIGNAL byebye
    SHELL COMMAND 'echo >'drive':RAWCMD "01"'		  /* rewind first   */
    edata = "19 01"
  END
  OTHERWISE
END

SHELL COMMAND 'echo >'drive':RAWCMD "'edata'"'

byebye:
  PANEL ON
  EXIT