/* 

   $VER: DMSWrite.filer 3.2 (12.6.95)

   Author:
    Matthias Scheler <tron@lyssa.owl.de>

   Function:
    Opens a string requester, asks for a drive and writes DMS file to the
    specified drive. After the DMS file has been written the user can
    decide to call the "Verify" command (include with Filer) to check the
    disk.

   History:
    2.1   added "PANEL OFF" and "PANEL ON"
    3.0   localized
    3.1   removed unnecessary ADDRESS 'FilerRexx'
    3.2   added "CALL" before "SETCLIP" to prevent search for "1.rexx"

   Requires:
    Bin/Verify

   Call:
    DMSWrite FILENAME

   Example for "Filer.RC":
    REXXCLASS "#?.dms","DMS!","DMSWrite %s"

*/

PARSE ARG FileName

OPTIONS RESULTS

Text1='Extract DMS file'
Text2='Enter target drive (e.g. "DF0:"):'
Text3='Extract DMS file aborted'
Text4='Extracting DMS file "'
Text5='" to "'
Text6='Check disk for read errors ?'
Text7='Extracted DMS file "'
Text8='" to "'

GETLANGUAGE
IF RESULT="deutsch" THEN
 DO
  Text1='DMS-Datei auspacken'
  Text2='Gegen Sie das Ziellaufwerk ein (z.B. "DF0:"):'
  Text3='Auspacken der DMS-Datei abgebrochen'
  Text4='Entpacke DMS-Datei "'
  Text5='" nach "'
  Text6='Diskette auf Lesefehler untersuchen ?'
  Text7='DMS-Datei "'
  Text8='" ausgepackt nach "'
 END

'STATUS '||Text1
PANEL OFF

DISKDRIVE=GETCLIP('FILER_DRIVE')
IF DISKDRIVE="" THEN DISKDRIVE='DF0:'

SETSTRING DISKDRIVE
'GETSTRING '||Text2
IF RESULT="RESULT" THEN
 DO
  PANEL ON

  'STATUS '||Text3
  EXIT 5
 END

DISKDRIVE=RESULT
CALL SETCLIP('FILER_DRIVE',DISKDRIVE)

'STATUS '||Text4||FileName||Text5||DISKDRIVE||'" ...'
EXECANDWAIT 'DMS WRITE ' FileName ' TO ' DISKDRIVE 'NOTEXT'

'QUESTBOX '||Text6
IF RESULT THEN EXEC 'Verify ' DISKDRIVE 'NOWAIT'

PANEL ON
'HISTORY 'Text7||FileName||Text8||DISKDRIVE||'".'