; Script to install Aerial Racers to Floppy Disk.
;


(complete 0)

(set mode (askchoice
            (help @askchoice-help)
            (prompt "Please select between installing Aerial Racers "
                    "from floppy disk to hard disk or from hard disk "
                    "to floppy disk.")
            (choices "Install to floppy"
                     "Install to hard disk")
            (default 0)
          )
)

(complete 10)

(if (= mode 0)
  (
    (message "The Aerial Racers floppy disk installation requires "
              "three blank floppy disks labeled:\n"
              "\nAerialRacers1\nAerialRacers2\nAerialRacers3\n\n"
              "The following libraries will be copied from your "
              "Libs: directory to AerialRacers1:\n\n"
              "diskfont.library\nmathtrans.library\n\n"
              "Make sure you have these disks ready..."
    )

    (askdisk
      (dest "AerialRacers1")
      (help @askdisk-help)
      (prompt "\nPlease insert the blank disk labeled AerialRacers1 into DF0:...")
    )

    (run "install df0:")

    (copylib
      (source "libs:diskfont.library")
      (dest "AerialRacers1:libs")
    )

    (copylib
      (source "libs:mathtrans.library")
      (dest "AerialRacers1:libs")
    )

    (copyfiles
      (source "AerialData")
      (dest "AerialRacers1:AerialData")
      (all)
    )

    (copyfiles
      (source "CommonData")
      (dest "AerialRacers1:CommonData")
      (all)
    )

    (copyfiles
      (source "s")
      (dest "AerialRacers1:s")
      (all)
    )

    (copyfiles
      (source "Tracks")
      (dest "AerialRacers1:Tracks")
      (all)
    )

    (copyfiles
      (source "AerialRacers")
      (dest "AerialRacers1:")
      (infos)
    )

    (copyfiles
      (source "TrackEditor")
      (dest "AerialRacers1:")
      (infos)
    )
    
    (copyfiles
      (source "AR.Guide")
      (dest "AerialRacers1:")
      (infos)
    )
    
    (copyfiles
      (source "AR.Install")
      (dest "AerialRacers1:")
      (infos)
    )
    
    (copyfiles
      (source "Disk1")
      (dest "AerialRacers1:")
    )
    
    (complete 40)
    
    (askdisk
      (dest "AerialRacers2")
      (help @askdisk-help)
      (prompt "\nPlease insert the blank disk labeled AerialRacers2 into any drive...")
    )
    
    (copyfiles
      (source "SceneryData")
      (dest "AerialRacers2:SceneryData")
      (all)
    )
    
    (copyfiles
      (source "Disk2")
      (dest "AerialRacers2:")
    )
    
    (complete 70)
    
    (askdisk
      (dest "AerialRacers3")
      (help @askdisk-help)
      (prompt "\nPlease insert the blank disk labeled AerialRacers3 into any drive...")
    )
    
    (copyfiles
      (source "AerialCars")
      (dest "AerialRacers3:AerialCars")
      (all)
    )
    
    (copyfiles
      (source "CommonData")
      (dest "AerialRacers3:CommonData")
      (all)
    )

    (copyfiles
      (source "Disk3")
      (dest "AerialRacers3:")
    )

    (set @default-dest "AerialRacers1:")
  )

  (
    (set dest_dir
      (tackon (askdir
                (prompt "Where do you want to install Aerial Racers?\n"
                        "A drawer called AerialRacers will be created.")
                (help @askdir-help)
                (default "Work:")
                (disk)
              )
              "AerialRacers"
      )
    )

    (makedir dest_dir (infos))

    (askdisk
      (dest "AerialRacers1")
      (help @askdisk-help)
      (prompt "\nPlease insert AerialRacers1 into any drive...")
    )

    (copyfiles
      (source "AerialRacers1:")
      (dest dest_dir)
      (all)
      (infos)
    )

    (complete 40)

    (askdisk
      (dest "AerialRacers2")
      (help @askdisk-help)
      (prompt "\nPlease insert AerialRacers2 into any drive...")
    )

    (copyfiles
      (source "AerialRacers2:")
      (dest dest_dir)
      (all)
      (infos)
    )

    (complete 70)

    (askdisk
      (dest "AerialRacers3")
      (help @askdisk-help)
      (prompt "\nPlease insert AerialRacers3 into any drive...")
    )

    (copyfiles
      (source "AerialRacers3:")
      (dest dest_dir)
      (all)
      (infos)
    )

    (set @default-dest dest_dir)

  )

)

(complete 100)

(exit)