G4C

winbig -1 -1 250 97 "Install"
wintype 11110001
winout "con:0/11/600/200/Installer Output/auto close"
varpath ''

xonload
set editor sys:dtp/bed/bed
extract install guipath inst_path
assign inst: $inst_path
delvar inst_path
guiopen install

xonopen
setgad install 2 off

xonclose
assign inst: remove
quit

box 0 0 250 60 out button
box 0 85 250 12 out button
ctext 10 5 "Please select where you wish" topaz.font 8 1 0 000
ctext 10 15 "to install CLIMasterII by" topaz.font 8 1 0 000
ctext 10 25 "either entering the full path" topaz.font 8 1 0 000
ctext 10 35 "into the string gadget below" topaz.font 8 1 0 000
ctext 10 45 "or use the Browse button." topaz.font 8 1 0 000

xtextin 0 60 250 13 "" cmpath "" 512
gadid 1
if $cmpath = ""
    ezreq "You MUST supply a path." Okay ""
    setgad install 1 on
    stop
else
    setgad install 2 on
endif

xbutton 0 73 80 12 Browse
reqfile -1 -1 240 -60 "Choose Path..." dir cmpath SYS:
if $cmpath > ""
    update install 1 $cmpath
    setgad install 2 on
endif

xbutton 80 73 90 12 Proceed
gadid 2
update install 3 "Installing CliMaster..."
copy inst:CliMasterII $cmpath
joinfile $cmpath CliMasterII.info desticon
copy inst:drawer $desticon
ifexists assign GUIS
    ;nop
else
    copy inst:gc fonts:
    copy inst:gc.font fonts:
    copy inst:Gui c:
    copy inst:Gui4Cli c:
endif
update install 3 "Install Complete!"
delay 50
guiclose install

xbutton 170 73 80 12 Cancel
guiclose install

text 10 85 230 12 "" 40 nobox
gadid 3