;----------------------------
;try to figure out a place where the user usually installs his games
(if (exists "Games:" (noreq) )
    (set @default-dest "Games:")
    (if (exists "SYS:Games" (noreq) )
        (set @default-dest "SYS:Games")
        (if (exists "Work:Games" (noreq) )
            (set @default-dest "Work:Games")
            (if (exists "JEUX:" (noreq) )
               (set @default-dest "JEUX:")
               (set @default-dest "SYS:")
            )
        )
    )
)



(set @default-dest
(askdir
	(prompt ("Where should %s installed ?\nA drawer \"%s\" will automatically created." @app-name @app-name))
	(help @askdir-help)
	(default @default-dest)
	(disk)
)
)

(set #dest (tackon @default-dest @app-name))

(set #CI_unit
	(askchoice
		(prompt "From which disk unit do you want\nto install the game")
		(help	@askoptions-help)
		(choices
		   "DF0:"
		   "DF1:"
		   "DF2:"
		   "DF3:"
		)
	)
)

(set #CI_drive ("DF%ld:" #CI_unit))


(makedir #dest
	(help @makedir-help)
	(infos)
)


;----------------------------

(copyfiles
	(help @copyfiles-help)
	(source "Supercars2HD")
	(dest #dest)
	(infos)
)

(copyfiles
	(help @copyfiles-help)
	(source "sc2hd.readme")
	(dest #dest)
	(infos)
)

(message ("\nInsert %s disk 1 into drive %s !" @app-name #CI_drive))
	(if
		(= 0 (run ("grem2file %ld \"%s\" 2 157 >con:///1000//CLOSE/WAIT" #CI_unit (tackon #dest "SC2.d1") )))
		("")
		(abort "\"grem2file\" must be in your PATH !")
	)

(message ("\nInsert %s disk 2 into drive %s !" @app-name #CI_drive))
	(if
		(= 0 (run ("grem2file %ld \"%s\" 2 151 >con:///1000//CLOSE/WAIT" #CI_unit (tackon #dest "SC2.d2") )))
		("")
		(abort "\"grem2file\" must be in your PATH !")
	)


(exit)