; Install Image Engineer V2.1
; © 1995 Simon Edwards
; This script installs Image Engineer.  Checks for need libraries, OS version
; CPU, installs IE.config to S: and adds an assign to user-startup.

(transcript "Installing Image Engineer...")

(set #intromsg (cat	"\nThis installs Image Engineer V2.1 on your\n"
			"hard disk and checks your Kickstart, CPU, and\n"
			"installed libraries.\n"))

(message #intromsg)

	;Check to see what version of the OS we're running on.
(if (< (/ (getversion) 65536) 37)
	(
	(if (<> 1 (askbool (help @askbool-help) (prompt (cat "You must be using Kickstart 2.04+ to run Image Engineer.\n"
					"\n"
					"Do you wish to continue anyway?\n"))))

		(
		(abort "Aborting as the Kickstart is not sufficient.")
		)
	)
	)
)


	; Check to see what CPU we're running on.
(if (>= 68020 (database "cpu"))
	(
	(if (<> 1 (askbool (help @askbool-help) (prompt (cat
					"\nYou need a 68020 CPU or better to run Image Engineer.\n"
					"\nDo you wish to continue anyway?\n"))))
		(
		(abort "Aborting as the CPU is not sufficient.")
		)
	)
	)
)


	;Check to see if superview.library is installed.
(if (exists "LIBS:superview.library")
	(
	(set vernum (getversion "LIBS:superview.library"))
	(if (< vernum (+ (* 11 65536) 10)) 
		(
		(set ver (/ vernum 65536))
		(set rev (- vernum (* ver 65536)))
		(message (cat (
			"\nYou have V%ld.%ld of superview.library,\n" ver rev)
			"although Image Engineer will run with this version\n"
			"I recommend that you get V11.10 from Aminet or your\n"
			"local PD library. (See docs)."))
		)
	)
	)

	(
	(if (<> 1 (askbool (help @askbool-help) (prompt 	
		(cat	"\nYou don't seem to have superview.library installed\n"
			"on your system.  Image Engineer needs at least V7.0\n"
			"of superview.library in order to run.\n\n"
			"Do you wish to continue anyway?\n"))))
			(

			(abort (cat
				"Aborting...\n\n"
				"The latest version of superview.library\n"
				"should be available from an Aminet site\n"
				"or PD library near you.\n"))
			)

	)
	)
)

	;Get the destination directory from the user
(set wheredir
	(askdir
	(prompt "Select a directory where you would like to install "
		"Image Engineer. (A drawer will be created there)")
	(help @askdir-help)
	(default @default-dest)
	)
)

	;Create the directory for Image Engineer
(set wheredir (tackon wheredir "ImageEngineerV2.1"))
(makedir wheredir (infos))


(working "Installing Image Engineer...")
	;Copy all of the files over to the destination
(copyfiles
	(prompt "")
	(help @copyfiles-help)
	(pattern "~(Install|Install.info)")
	(infos)
	(source (pathonly @icon))
	(dest wheredir)
)

	;Add an assign to user startup
(startup "IMAGEENGINEER"
	(prompt "I need to add an assign to your\n\"s:user-startup\" file.")
	(help @startup-help)
	(command ("assign IE: \"%s\"\n" wheredir))
)

	;Copy new IE.config file to S:
(if (exists "s:IE.config")
	(
	(if (<> (getsize "s:IE.config") 5238)
		(
		(copyfiles (prompt "Copying new IE.config") (help @copyfiles-help) 
			(source "IE.config") (dest "s:") (files))
		)

		(
		(if (askbool (help @askbool-help) (prompt 	
			(cat	"\nMay I copy the new IE.config over\n"
				"your current IE.config file?\n")))
				(
				(copyfiles (prompt "Copying new IE.config") (help @copyfiles-help) 
					(source "IE.config") (dest "s:") (files))
				)

			)
		)
		)
	)

	(
	(copyfiles (prompt "Copying new IE.config") (help @copyfiles-help) 
		(source "IE.config") (dest "s:IE.config"))
	)
)

(exit "Please reboot your computer before running\nImage Engineer.")