; $VER: Install_Nucleus 1.0 (20.10.95)
; Install script for Nucleus

(set #install-msg "\n\Nucleus installation script.\nThis script installs Nucleus on your Amiga.\n\nRead the Documentation files for\nmore information on the distribution.\nNucleus © 1995 Jon Close\nAll rights reserved.")
(set #install-dir "Where do you wish to put Nucleus?")
(set #bad-kick "You must be using Kickstart 2.04 to use Nucleus. Aborting!")
(set #old-reqtools "\n\nYou are using a version of reqtools.library\nolder than V38.\nI will now try to install reqtool.library V38")

;========================================================
; Check system we`re running on


(if (< (/ (getversion) 65536) 37)
(
                (abort #bad-kick)
))

;========================================================
; Get destination for Nucleus

(set srcdir "")

(set destdir
        (askdir
                (prompt #install-dir)
                (help @copyfiles-help)
                (default "Work:")
        )
)

(set @default-dest destdir)

(makedir (tackon destdir "Nucleus")(infos))

(complete 10)

;========================================================
; Copy Main Program

(copyfiles
        (prompt "Copying Nucleus to destination.")
        (help @copyfiles-help)
        (source srcdir)
        (dest (tackon destdir "Nucleus"))
        (choices "Nucleus" "Nucleus.guide")
        (infos)
        (confirm)
)

(complete 30)

;========================================================
; Copy Program Font (If Nucleus not installed then jump to installing examples)

(if (NOT (= (exists "FONTS:Topal/8") 1))
(if (= (exists (tackon destdir "Nucleus/Nucleus")) 1)
(copyfiles
        (prompt "Copying Program Font to destination.")
        (source (tackon srcdir "Fonts"))
        (dest "FONTS:")
        (pattern "Topal#?")
)
)
)

(complete 40)

    ;========================================================
    ; Copy Icons

(copyfiles
        (prompt "Copying Icons to destination.")
        (source (tackon srcdir "Icons"))
        (dest (tackon destdir "Nucleus/Icons"))
        (all)
        (infos)
)

(complete 50)

    ;========================================================
    ; Check version of ReqTools

(if (< (/ (getversion "reqtools.library" (resident)) 65536) 38)
(
        (message #old-reqtools)

        (copylib
                (prompt ("\n\nInstalling reqtools.library"))
                (help @copylib-help)
                (source (tackon srcdir "libs/reqtools.library"))
                (dest "LIBS:")
        (confirm)
        )
)

)

(complete 60)

;========================================================
; Copy Example Executables

(copyfiles
        (prompt "Copying Examples to destination.")
        (help @copyfiles-help)
        (source (tackon srcdir "Examples"))
        (dest (tackon destdir "Nucleus/Examples"))
        (pattern "~(about|pixel)")
        (infos)
        (confirm)
)

(if (= (exists (tackon destdir "Nucleus/Examples/Nucleus.exe")) 1)
    (copyfiles
        (prompt "Copying Examples to destination.")
        (help @copyfiles-help)
        (source (tackon srcdir "Examples"))
        (dest (tackon destdir "Nucleus/Examples"))
        (pattern "#?(about|pixel)")
    )
)

(complete 80)


;========================================================
; Copy Example Data


(copyfiles
        (prompt "Copying Example Data to destination.")
        (help @copyfiles-help)
        (source (tackon srcdir "Data"))
        (dest (tackon destdir "Nucleus/Data"))
        (pattern "#?")
        (infos)
        (confirm)
)


(complete 90)


;========================================================
; Copy Example Fonts


(if (NOT (= (exists "FONTS:Pc_venus/15") 1))
(if (OR (= (exists (tackon destdir "Nucleus/Examples/DigiPix.exe")) 1) (= (exists (tackon destdir "Nucleus/Data/DigiPix.mnu")) 1))
    (copyfiles
        (prompt "Copying Example Fonts....")
        (help @copyfiles-help)
        (source (tackon srcdir "fonts"))
        (dest "FONTS:")
            (pattern "Pc_venus#?")
    )
)
)

(if (NOT (= (exists "FONTS:Ruby/15") 1))
(if (OR (= (exists (tackon destdir "Nucleus/Examples/PixelDigital.exe")) 1) (= (exists (tackon destdir "Nucleus/Data/PixelDigital.mnu")) 1))
    (copyfiles
        (prompt "Copying Example Fonts....")
        (help @copyfiles-help)
        (source (tackon srcdir "fonts"))
        (dest "FONTS:")
            (pattern "Ruby#?")
    )
)
)

(complete 100)

(exit)