@echo off
rem
rem              Install program for PC-Dragon Emulator
rem
rem                     Usage: INSTALL [drive:]
rem
if not exist dragon.exe goto seekunzip
echo.
echo This program should be used to install PC-Dragon from a .ZIP archive
echo on a floppy disk onto your hard disk.
echo You don't appear to need to run this program.
echo.
goto exit
:seekunzip
if exist pkunzip.exe goto found
if exist a:\pkunzip.exe goto afound
if exist b:\pkunzip.exe goto bfound
goto wrongdir
:afound
a:
goto root
:bfound
b:
:root
cd\
:found
if not %1.==. goto install
if exist install.bat install c:
:wrongdir
echo.
echo Please run INSTALL from same directory as ZIP file.
echo.
goto exit
:install
if exist %1\pcdragon\*.* goto already
if exist %1\*.* goto okay
if exist %1\NUL goto okay
:usage
echo.
echo Usage: INSTALL [drive:]
echo.
goto exit
:already
echo.
echo You already have a copy of PC-Dragon on the disk.
echo Please remove the old version first if you wish to upgrade.
echo.
goto exit
:okay
pkunzip -d pcdgn102 %1\pcdragon
if exist *.dgn copy *.dgn %1\pcdragon
if exist *.cas copy *.cas %1\pcdragon\cassette
if exist archive\*.cas copy games\*.cas %1\pcdragon\cassette\archive
if exist games\*.cas copy games\*.cas %1\pcdragon\cassette\games
if exist d32rom.zip pkunzip -d d32rom %1\pcdragon
if exist d64rom.zip pkunzip -d d64rom %1\pcdragon
if exist d64rom2.zip pkunzip -d d64rom2 %1\pcdragon
if exist tandyrom.zip pkunzip -d tandyrom %1\pcdragon
if exist dragrom.zip pkunzip -d dragrom %1\pcdragon
if exist dragroms.zip pkunzip -d dragroms %1\pcdragon
if exist dragames.zip pkunzip -d dragames %1\pcdragon\cassette\games
%1
cd\pcdragon
if not exist runme.bat goto exit
if exist install.bat del install.bat
echo.
echo.
echo.
echo Now Executing RUNME.BAT:
echo ~~~~~~~~~~~~~~~~~~~~~~~~
call runme
:exit