REM     THIS PROGRAM IS FREEWARE!
REM
REM     This is a simple QBASIC program which is intended to be used with
REM     the TRANSDISK program. Since there were no easy way to copy those
REM     files directly from the COMx: port under MSDOS (i tried) i  wrote
REM     this in couple of minutes.
REM
REM     Quick Operating instructions.
REM
REM     1) Connect your _AMIGA_ to your PC
REM     2) Set the serial options from your amiga to 19200,8,N,1 or slower
REM     3) Modify this source to meet the demands of the transfer
REM        (On the line 2 after the begining of "opencom" subprogram)
REM     4) Run the program

init:
    DIM char$(1024)
    ON ERROR GOTO errh
    CLS
PRINT "ÉÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍ»"
PRINT "º                Amiga Disk File Importer for MS-DOS                 º"
PRINT "º                 Copyright (c) 1996 Henry Mantere.                  º"
PRINT "º                    Version 1.1B - 08111996.002                     º"
PRINT "ÈÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍÍͼ"
    GOTO main

errh:
    err1 = ERR
    IF allowerror = 0 THEN
        LOCATE 2, 76: PRINT err1;
        RESUME NEXT
        allowerror = 1
    ELSE
        LOCATE 22, 1
        PRINT "Unexpected runtime-error ("; err1; "). Program halted."
        END
    END IF

main:
    INPUT "Enter Filename: "; filename$: filename$ = UCASE$(filename$)
     GOSUB csl: LOCATE 22, 1: PRINT "Opening output file."
    GOSUB openfile:
     GOSUB csl: LOCATE 22, 1
     PRINT "Waiting serial port to respond (responds when data send)."
    GOSUB opencom:
    LOCATE
    LOCATE 7, 1: PRINT "  Bytes Received:"; count
    LOCATE 8, 1: PRINT "     Bytes to go:"; 901120 - count
    LOCATE 9, 1: PRINT "Transfer started: "; TIME$
    LOCATE 10, 1: PRINT "    Current time: "; TIME$
    WHILE count < 901120
        count = count + 1024
        FOR a = 0 TO 1023
            char$(a) = INPUT$(1, 2)
        NEXT
        FOR a = 0 TO 1023
            PRINT #1, char$(a);
        NEXT
        LOCATE 7, 1: PRINT "  Bytes Received:"; count
        LOCATE 8, 1: PRINT "     Bytes to go:"; 901120 - count; "    "
        LOCATE 10, 1: PRINT "    Current time: "; TIME$
    WEND
    BEEP: BEEP
    GOSUB csl: LOCATE 22, 1: PRINT "Transfer operation complete."
    END

openfile:
    err1 = 0: allowerror = 0
    OPEN filename$ FOR INPUT AS 1
    IF err1 = 53 THEN
        CLOSE 1
        OPEN filename$ FOR OUTPUT AS 1
    ELSE
         GOSUB csl: LOCATE 22, 1
         PRINT "File ("; filename$; ") already exists, ";
        INPUT "overwrite (y/N)"; a$: a$ = UCASE$(a$)
        IF a$ = "Y" THEN
            CLOSE 1
            OPEN filename$ FOR OUTPUT AS 1
        ELSE
            GOSUB csl: LOCATE 22, 1
            PRINT "File ("; filename$; ") could not be opened for output."
            END
        END IF
    END IF
    RETURN

opencom:
    err1 = 0: allowerror = 0
    OPEN "com2:19200,N,8,1,BIN" FOR INPUT AS 2
REM <Modify the line above, if needed>
    IF err1 = 24 THEN
                      GOSUB csl: LOCATE 22, 1
                      PRINT "Timeout on serial port."
                      GOTO opencom
                 END IF
    RETURN

csl:                  
    LOCATE 22, 1: FOR a = 0 TO 78: PRINT " "; : NEXT: PRINT " "
    RETURN